Assistance with Mathematica: using /. replace method with IF[] conditional

Question

Let me first state that I am a Mathematica novice and this question is probably easily answered, but I have so far not been able to find any help for this specific problem scouring the internet. Here, I've basically summarized what I need my code to do. There is some problem using the /. replace command with the IF conditional statement. Basically, I have a very long function which contains another function which is defined globally by an IF conditional. These few lines of code demonstrate the error I am running into...

In[1]:= y[x_, z_] = 2*x + 3*z;

In[2]:= zz[x_, z_] := If[y[x, z] < 0, 4*y[x, z], y[x, z]]

In[3]:= zz[-1, -2]

Out[3]= -32

But I need...

In[4]:= zz[x_, z_] /. x -> -1 /. z -> -2

Out[4]= If[3 Pattern[-2, _] + 2 Pattern[-1, _] < 0, 
 4 y[Pattern[-1, _], Pattern[-2, _]], 
 y[Pattern[-1, _], Pattern[-2, _]]]

which does not yield the expected numeric term. Thanks in advance to all of you for your help, despite how silly this question may sound. Note: I must use the replace command as opposed to directly assigning a value to x and z.

ADDENDUM:

I simplified my example too much. Take this example:

In[91]:= a[b_, c_] = -3*b + 2*c + d + e + f;

In[92]:= g[b_, c_] := If[a[b, c] < 0, -3*a[b, c], a[b, c]];

In[10]:= g[2, 4] /. d -> 1 /. e -> 2 /. f -> 3

Out[10]= 2 + d + e + f

But I expect to see the result Out[10]= 8

Hopefully another easy fix.

Answer 1

When you define a function, you use x_, which tells mathematica to find the pattern named x and apply the definition to it. So f[x_]=x^2 says "take the expression x and transform it as Power[x,2]".

When you call a function, you don't use a pattern anymore, but rather use a variable or a value that mathematica eventually substitutes for x. So f[a] will give you a^2 if a is undefined, or use the definition for a and give the result accordingly.

So as Howard mentioned in the comment, if you simply remove the underscores, you'll get the expression you want.

In[1]:= zz[x, z] /. x -> -1 /. z -> -2

Out[1]= -32

EDIT

To answer your comment,

If evaluates the second and third arguments only after the condition is evaluated. So if you look at g[2,4], you get

If[2 + d + e + f < 0, -3 a[2, 4], a[2, 4]]

you see that "then" and "else" statements remain unevaluated, although a[2,4] by itself gives you 2 + d + e + f.

So, when you do the replacements, mathematica begins replacing d,e,f where ever it finds in the expression (which is only in the condition) and once it evaluates the condition and reaches the "then" or "else" steps, there is nothing else to replace.

What you need to use is ReplaceAll or //. which repeatedly applies the rules until it can no longer be applied. Here's how

In[2]:= rules = {d -> 1, e -> 2, f -> 3};
        g[2, 4] //. rules
Out[2]= 8

Answer 2

I suggest this variation of your "Addendum" code:

a[b_, c_] = -3*b + 2*c + d + e + f;

g[b_, c_] := If[# < 0, -3*#, #] & @ a[b, c]

g[2, 4] /. {d -> 1, e -> 2, f -> 3}

(* Out = 8 *)

The changes are:

1. Move the If statement into a pure function separate from a[b, c]. This way a[b, c] is only evaluated once, which is generally a good practice.

2. Move your replacements into a single /. operation and a list of rules. Again, good practice, unless you actually intend a serial replacement.

In this case, the first change solves your problem, because g[2, 4] evaluates to:

If[2 + d + e + f < 0, -3 (2 + d + e + f), 2 + d + e + f]

which explicitly uses d, e, and f. These are therefore visible to ReplaceAll (/.) and the replacements work correctly.

It is plausible that there is a better way to accomplish your goal, but I will refrain from guessing the rest of your code.