XPath statement to find count same preceding sibling

Question

I have the following XML structure

<containers>
    <container type="1"></container>
    <container type="2"></container>
    <container type="2"></container>
    <container type="1"></container>
    <container type="2"></container>
    <container type="2"></container>
    <container type="2"></container> 
</containers>

I want to find the count of immediate preceding-sibling of the same type. How can check in XSLT e.g.

for 1st container count of preceding-sibling of same type = 0
for 2st container count of preceding-sibling of same type = 0
for 3rd container count of preceding-sibling of same type = 1
for 4th container count of preceding-sibling of same type = 0
for 5th container count of preceding-sibling of same type = 0
for 6th container count of preceding-sibling of same type = 1
for 7th container count of preceding-sibling of same type = 2

my XSLT condition

    <xsl:choose>
  <xsl:when test="count(preceding-sibling::*[type = 2]) mod 2 = 0">
    <xsl:attribute name="class">classX</xsl:attribute>
  </xsl:when>
  <xsl:otherwise>   
  </xsl:otherwise>
</xsl:choose>

XSLT 2 or 3 should allow that using `for-each-group group-adjacent` — Martin Honnen, Jan 21 '20 at 12:09
thanks for reply, I want to use this is in condition. do you have any example of it — Binjan, Jan 21 '20 at 12:24

zx485 · Answer 1 · 2020-01-21T15:28:48.727

In XSLT-2.0 this is easy:

<xsl:template match="containers">
  <xsl:copy>
    <xsl:for-each-group select="container" group-adjacent="@type">
      <xsl:for-each select="current-group()">
        <container>
            <xsl:copy-of select="@*" />
            <xsl:attribute name="class"><xsl:value-of select="position()-1" /></xsl:attribute>
        </container>
      </xsl:for-each>
    </xsl:for-each-group>
  </xsl:copy>
</xsl:template>

Its output is:

<?xml version="1.0" encoding="UTF-8"?>
<containers>
   <container type="1" class="0"/>
   <container type="2" class="0"/>
   <container type="2" class="1"/>
   <container type="1" class="0"/>
   <container type="2" class="0"/>
   <container type="2" class="1"/>
   <container type="2" class="2"/>
</containers>

An XSLT-1.0 solution is this (Inspired by this SO answer):

<xsl:template match="containers">
  <xsl:copy>
    <xsl:for-each select="container">        
      <container>
        <xsl:copy-of select="@*" />
        <xsl:attribute name="class"><xsl:value-of select="count(preceding-sibling::container) - count(preceding-sibling::container[@type!=current()/@type][1]/preceding-sibling::container | preceding-sibling::container[@type!=current()/@type][1])" /></xsl:attribute>
      </container>
    </xsl:for-each>
  </xsl:copy>
</xsl:template>

It is more complicated and slower - and far less elegant. But it does its job. The output is the same.

@Binjan: I added an XSLT-1.0 solution to my answer. – zx485 Jan 21 '20 at 15:29 — zx485, Jan 21 '20 at 15:29

score 0 · Answer 2 · answered Jan 21 '20 at 12:40

In XSLT 3, you could implement it using an accumulator:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    exclude-result-prefixes="#all"
    version="3.0">

  <xsl:mode on-no-match="shallow-copy" streamable="yes" use-accumulators="type-count"/>

  <xsl:accumulator name="type-count" as="map(*)" initial-value="map{}" streamable="yes">
      <xsl:accumulator-rule match="containers" select="map {}"/>
      <xsl:accumulator-rule
        match="containers/container"
        select="map { 
                  'type' : string(@type), 
                  'count' :
                     if (not(@type = $value?type))
                     then 0
                     else $value?count + 1
                }"/>
  </xsl:accumulator>

  <xsl:template match="container">
      <xsl:copy>
          <xsl:apply-templates select="@*"/>
          <xsl:attribute name="sibling-count" select="accumulator-before('type-count')?count"/>
      </xsl:copy>
  </xsl:template>

</xsl:stylesheet>

https://xsltfiddle.liberty-development.net/gWEaSuW

Or, for your example, to check and create an attribute:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    exclude-result-prefixes="#all"
    version="3.0">

  <xsl:mode on-no-match="shallow-copy" streamable="yes" use-accumulators="type-count"/>

  <xsl:accumulator name="type-count" as="map(*)" initial-value="map{}" streamable="yes">
      <xsl:accumulator-rule match="containers" select="map {}"/>
      <xsl:accumulator-rule
        match="containers/container"
        select="map { 
                  'type' : string(@type), 
                  'count' :
                     if (not(@type = $value?type))
                     then 0
                     else $value?count + 1
                }"/>
  </xsl:accumulator>

  <xsl:template match="container">
      <xsl:copy>
          <xsl:apply-templates select="@*"/>
          <xsl:if test="accumulator-before('type-count')?count mod 2 = 0">
              <xsl:attribute name="class">classX</xsl:attribute>
          </xsl:if>
      </xsl:copy>
  </xsl:template>

</xsl:stylesheet>

https://xsltfiddle.liberty-development.net/gWEaSuW/1

@Binjan, on many platforms like Java or .NET it is easy to switch to Saxon 9 to use XSLT 2 or 3, that would be my first suggestion. But I am sure others will come up with an XSLT 1 way if you need it. — Martin Honnen, Jan 21 '20 at 13:26

XPath statement to find count same preceding sibling

2 Answers2