Renaming and Deleting attributes in same array using dataweave

Question

My sample input payload is given below:

{
  "entities": [
{
  "Id": "ab5fdd89e123",
  "target": {
    "Data": {
      "attributes": {
        "Name": [],
        "Address": [
          {
            "value": {
              "AddType": [{"value": "MAIN"}],
              "Flag": [{"value": true }]
                     }
}]}}}}]}

I need to replace the attribute called Flag (target.Data.attributes.Address.value.Flag) to "PrimaryFlag" with value as true. I also need to add a new attribute after that called "Code" with value as null. The desired output should be as below:

{
  "entities": [
    {
      "Id": "ab5fdd89e123",
      "target": {
        "Data": {
          "attributes": {
            "Name": [],
            "Address": [
              {
                "value": {
                  "AddType": [{"value": "MAIN"}],
                  "PrimaryFlag": [{"value": true }],
                  "Code": [{"value": null}]
                         }
}]}}}}]}

I'm running Mule 3.9 and is on dataweave 1.0

George · Accepted Answer · 2020-01-21T22:10:37.520

Try this--it contains comments:

%dw 1.0
%output application/dw
%var data = {
    "entities": [
        {
            "Id": "ab5fdd89e123",
            "target": {
                "Data": {
                    "attributes": {
                        "Name": [],
                        "Address": [
                            {
                                "value": {
                                    "AddType": [
                                        {
                                            "value": "MAIN"
                                        }
                                    ],
                                    "Flag": [
                                        {
                                            "value": true
                                        }
                                    ]
                                }
                            }
                        ]
                    }
                }
            }
        }
    ]
}

// Traverse a data structure
// When you traverse an object:
//   1) Get the fields as strings
//   2) Test whether you have a field Flag in your fields
//   3) If you do then rename Flag to PrimaryFlag and add 
//      the Code field to the current object
//      Traversal stops at this point
//   4) If you don't then just traverse object and recursivelly
//      traverse the values
// When you traverse an array:
//   1) Iterate over the array
//   2) Traverse every single element in the array
// For all other types default will execute.
%function traverse(ds) ds match {
    :object -> using (
        fs = $ pluck $$ as :string
    ) (
        (
            $ - "Flag" ++ {PrimaryFlag: $.Flag,Code: [{code: null}]} 
            when (fs contains "Flag")
            otherwise ($ mapObject {($$): traverse($)})
        )
    ),
    :array -> $ map traverse($),
    default -> $
}

---
traverse(data)

I had to make some assumptions, for example the field Flag is not nested in your your data structure.

Thank you for answering with detailed explanation. I will try this out :-) — Triumph Spitfire, Jan 21 '20 at 16:34
Instead of having "Code" under Address, can it be added as another attribute (after Address) ? — Triumph Spitfire, Jan 22 '20 at 06:54
Child of `attributes`? Yes it can, I will adjust the code sometime today. — George, Jan 22 '20 at 15:52
Thanks @George I copied your answer to DW, it says invalid input `{ ` — star, Jan 22 '20 at 20:55
I suspect you mean DW 1.0 @star and not DW 2.0. It should work verbatim as is if you cut-n-paste the whole thing. If you used a different input please share. — George, Jan 22 '20 at 22:13
@George True. Do i need to change anything specific to DW2. Im trying to lower the version. Taking longer time to load — star, Jan 22 '20 at 22:30
@TriumphSpitfire I am adding another answer with the mods you requested. — George, Jan 22 '20 at 22:45

score 1 · Answer 2 · answered Jan 22 '20 at 22:47

This should allow you to rename Flag to PrimaryFlag and also add Code: [{code: null}] as a child field to attributes

%dw 1.0
%output application/dw
%var data = {
    "entities": [
        {
            "Id": "ab5fdd89e123",
            "target": {
                "Data": {
                    "attributes": {
                        "Name": [],
                        "Address": [
                            {
                                "value": {
                                    "AddType": [
                                        {
                                            "value": "MAIN"
                                        }
                                    ],
                                    "Flag": [
                                        {
                                            "value": true
                                        }
                                    ]
                                }
                            }
                        ]
                    }
                }
            }
        }
    ]
}

// Traverse a data structure
// When you traverse an object:
// 1) iterate over the fields and values using the mapObject operator
// 2) If the field is "Flag" then rename it to PrimaryFlag
// 3) If the field is "attributes" then add the {Code: [value: null]}
//    as a child node otherwise add the empty object, which will leave
//    the original object unchanged
// When you traverse an array:
//   1) Iterate over the array
//   2) Traverse every single element in the array
// For all other types default will execute.
%function traverse(ds) ds match {
    :object -> $ mapObject {
            (
                "PrimaryFlag" when ($$ as :string == "Flag") otherwise $$
            ): traverse($) ++ ({Code: [value: null]} when ($$ as :string == "attributes") otherwise {})
    },
    :array -> $ map traverse($),
    default -> $
}

---
traverse(data)

This version keeps iterating and it will go to the end of your tree.

Renaming and Deleting attributes in same array using dataweave

2 Answers2