Is there a function in PineScript for calculating the number of bars displayed?

Question

What I want to get is the length of the series displayed on screen. Is this possible or must one specify length?

Answer 1

if you want to count the number of bars from a specific time period, then here's the pine script for this:

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © PHStudios

//@version=4
study("Candle Counter", shorttitle="CCount", overlay=true)

timeYear = input(2021, title="Year", minval=1991, maxval=2100, type=input.integer)
timeMonth = input(6, title="Month", minval=1, maxval=12, type=input.integer)
timeDay = input(21, title="Day", minval=1, maxval=31, type=input.integer)
timeHours = input(9, title="Hours", minval=0, maxval=23, type=input.integer)
timeMinutes = input(15, title="Minutes", minval=0, maxval=59, type=input.integer)
timeSeconds = input(0, title="Seconds", minval=0, maxval=59, type=input.integer)

// Initilization of variables only once
var greenCandleCount = 0 
var redCandleCount = 0
var totalCandleCount = 0

// Reset Candle Count to 0 from a particular time interval
if(year == timeYear and month == timeMonth and dayofmonth == timeDay and hour == timeHours and minute == timeMinutes and second == timeSeconds)
    greenCandleCount := 0
    redCandleCount := 0
    totalCandleCount := 0

// Counting Total Number of Green, Red, and Sum of Both Candles
if(close > open)
    greenCandleCount += 1
    totalCandleCount += 1

if(open > close)
    redCandleCount += 1
    totalCandleCount += 1

plotchar(greenCandleCount, title="Green Bars", color=color.green, char='')
plotchar(redCandleCount, title="Red Bars", color=color.red, char='')
plotchar(totalCandleCount, title="Total Bars", color=color.black, char='')

Just select the exact date and time that you want to count the bars from and get the output plotted on the chart.

Answer 2

I have tested a simpler way to do it in version 5:

//Calculate the visible bars
tf = timeframe.in_seconds(timeframe.period) // Convert timeframe to int (number of seconds)
delta = chart.right_visible_bar_time  -  chart.left_visible_bar_time // Time diffemrence between rightmost and leftmost visible bars
barDuration = time - time[1] // Time difference between consecutive bars
numBars = math.ceil(delta / barDuration) // Number of visible bars

Answer 3

To know the number of the visibles bar on my tradingview screen, I made this little script.
It use chart.left_visible_bar_time and chart.right_visible_bar_time to get the range of the time displayed on my screen.
Then I use timeframe.period to get the resolution chosen for my screen.

After some calculation, because the string obtained by timeframe.period is a bit strange (You can get 1D, 2M ou 72...), I display the number of visible bars at the middle top of my screen.

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © mentalRock19315

//@version=5
indicator("Number of visible bars",overlay = true)
start_time = chart.left_visible_bar_time // get unix time in milli seconds
end_time = chart.right_visible_bar_time
resolution = timeframe.period
var affichage = table.new(position.top_center, 1,1,bgcolor=color.white)

if barstate.islastconfirmedhistory
    second_divider = 0
    // Convert the screen timeframe in seconds
    if str.contains(resolution, "S")
        if str.length(resolution) == 1
            second_divider := 1
        else
            second_divider := int(str.tonumber(str.substring(resolution, 0,str.length(resolution)-1)))
    else if str.contains(resolution, "D")
        if str.length(resolution) == 1
            second_divider := 60*60*24
        else
            second_divider := int(str.tonumber(str.substring(resolution, 0,str.length(resolution)-1)))*60*60*24
    else if str.contains(resolution, "W")
        if str.length(resolution) == 1
            second_divider := 60*60*24*7
        else
            second_divider := int(str.tonumber(str.substring(resolution, 0,str.length(resolution)-1)))*60*60*24*7
    else if str.contains(resolution, "M")
        if str.length(resolution) == 1
            second_divider := 60*60*24*365/12
        else
            second_divider := int(str.tonumber(str.substring(resolution, 0,str.length(resolution)-1)))*60*60*24*365/12
    else
        if str.length(resolution) == 1
            second_divider := 60
        else
            second_divider := int(str.tonumber(str.substring(resolution, 0,str.length(resolution)-1)))*60

    if second_divider > 0
        Visibles_bars = (end_time-start_time)/1000/second_divider + 1
        table.cell(affichage, column=0, row=0, text="Visible bars = " + str.tostring(Visibles_bars,"#"))

I made this open library on Pinescript you can use to get the number of visible bars, just import it in your code :

import mentalRock19315/NumberOfVisibleBars/3

and then you can get the number of visibles bars in the variable of your choice :

a = NumberOfVisibleBars.NumberOfVisibleBars()

I hope it helps.

Answer 4

I came up with a simpler solution that works correctly even with charts having discontinuous sessions.

Set the maximum no. of candles you would like to process.

Run this loop to find the number of visible bars:

    MAX_BAR_COUNT = 150
    numBars = 0 // Number of visible bars
    for int i = 0 to 1000
        if time[i] < chart.left_visible_bar_time
            break
        numBars += 1

Answer 5

//usable positive number
numBars := ta.valuewhen(time == chart.left_visible_bar_time, math.abs(bar_index - last_bar_index),0)