Trouble serializing vectors in a sub-class in AS3

Question

Hey there! I'm trying to serialize data in AS3 but am running into a frustrating problem. Originally I had problems with "myObjClass" not being convertible, but after I discovered "registerClassAlias" I got things working allright.

Some time later, I added vectors to the myObjClass. I ran into trouble with Vector Strings before, as was reported here:

https://bugs.adobe.com/jira/browse/FP-6693

So I know the workaround is to include:

registerClassAlias("String", String);

I'm just not sure how to register an alias for a subvector within a vector (along with other variables). Here's my code:

var newObj:myObjClass = new myObjClass();
newObj.mySubXML = new Vector.<XML>();
newObj.mySubString = new Vector.<String>();

var myObj:Vector.<myObjClass> = new Vector.<myObjClass>();
myObj.push(newObj);

registerClassAlias("String", String); // Problem #1
registerClassAlias("XML", XML);       // Problem #1
registerClassAlias("VecMyObjClass", Vector.<myObjClass> as Class); // Problem #2
// registerClassAlias("myObjClass", myObjClass); // This and the above are interchangable (same errors)
var bytes:ByteArray = new ByteArray();
bytes.writeObject(myObj);
bytes.position = 0;
myObj = bytes.readObject();

Problem #1: When these two lines are included in my compilation, the final line (bytes.readObject()) fails with the error:

Error #1034: Type Coercion failed: cannot convert __AS3__.vec::Vector.<Object>@42edb21 to __AS3__.vec.Vector.<myObjClass>.

This is really strange. It's as if the first two registerClassAlias's are undoing the third one.

Problem #2: If I comment out the two "first problem" lines (string/xml classalias registrations) it converts myObj to myObjClass just fine; no internal error is thrown and the application is not halted. However, it fails to convert the internal String and XML vectors, with this error appearing in the application Output (without halting):

TypeError: Error #1034: Type Coercion failed: cannot convert __AS3__.vec::Vector.<Object>@3aabc11 to __AS3__.vec.Vector.<XML>.
TypeError: Error #1034: Type Coercion failed: cannot convert __AS3__.vec::Vector.<Object>@3aabc41 to __AS3__.vec.Vector.<String>.

So my question is, How can I register a class alias for:

Vector.(myObjClass)
A vector of Strings as a property of Vector.(myObjClass)
A vector of XML as a property of Vector.(myObjClass)

All at the same time?

score 6 · Accepted Answer · answered May 14 '11 at 23:25

Looks like moving:

registerClassAlias("XML", XML);
registerClassAlias("String", String);

Into myObjClass directly did the trick, while retaining:

registerClassAlias("myObjClass", myObjClass);

In the serialization class. I'm not sure why storing the three together in the serialization class wasn't working - and was generating strange errors if I changed the order of the code, so the problem might just be some glitch on specific machine.

Simon Eyraud · Answer 2 · 2011-05-14T20:48:59.537

4

When you want to use a complex vector content, you have to register your each sub-class (for you Vector.[String]) as follow :

    package
{
    import flash.display.Sprite;
    import flash.net.registerClassAlias;
    import flash.utils.ByteArray;

    public class StackOverFlow extends Sprite
    {
        public function StackOverFlow()
        {
            var newObj:myObjClass = new myObjClass();
            newObj.mySubXML = new Vector.<XML>();
            newObj.mySubString = new Vector.<String>();

            var myObj:Vector.<myObjClass> = new Vector.<myObjClass>();
            myObj.push(newObj);

            registerClassAlias("String", String);
            registerClassAlias("XML", XML);
            registerClassAlias("myObjClass", myObjClass);
            registerClassAlias("VecMyObjClass", Vector.<myObjClass> as Class);
            var bytes:ByteArray = new ByteArray();
            bytes.writeObject(myObj);
            bytes.position = 0;
            myObj = bytes.readObject();
        }
    }
}

internal class myObjClass{
    public var mySubXML : Vector.<XML>;
    public var mySubString : Vector.<String>;
}

edited May 14 '11 at 20:48

answered May 11 '11 at 09:45

Simon Eyraud

2,445
1
20
22

Hmm, if myObjClass is a custom type that contains two vector sub-objects, how would it work? "myObjClass" isn't defined as "vector.string" it's defined as a set of properties; vector string, vector xml, lone string, etc – Andy Moore May 11 '11 at 16:59
As as said, you have to register each custom type and each vector type you use. Can you add more code ? – Simon Eyraud May 11 '11 at 19:05
Totally rewrote the question to hopefully make more sense. :) – Andy Moore May 14 '11 at 19:56
As drinkycode said, you forgot to register myObjClass (sorry drinkycode, I added my answer at the same time) – Simon Eyraud May 14 '11 at 20:53

score 2 · Answer 3 · answered May 14 '11 at 20:47

Testing your code Andy you need to register the class you created so bytes.readObject() returns a vector with the custom classes - in this case the class myObjClass. So if you add this line of code:

registerClassAlias("myObjClass", myObjClass);

So if you alter the code to look like this then you should return the object with all its data correctly serialized (I did a simple test and it seems to work on my end).

var newObj:myObjClass = new myObjClass();
newObj.mySubXML = new Vector.<XML>();
newObj.mySubString = new Vector.<String>();

var myObj:Vector.<myObjClass> = new Vector.<myObjClass>();
myObj.push(newObj);

registerClassAlias("String", String);
registerClassAlias("XML", XML);
registerClassAlias("myObjClass", myObjClass);
var bytes:ByteArray = new ByteArray();
bytes.writeObject(myObj);
bytes.position = 0;
myObj = bytes.readObject();

I replaced my registerAliasClass with yours (changing the registration from a Vector.(myObjClass) to just myObjClass) and I'm getting the exact same results - the XML and String registrations cause the myObjClass conversion to fail. When I comment them out it works fine (but then fails on the string+xml conversion). (Added a commented-out-line in the Q to reflect this) — Andy Moore, May 14 '11 at 21:11

score 1 · Answer 4 · answered Jul 03 '11 at 11:47

registerClassAlias("String", String);    
registerClassAlias("VecString", Vector.<String> as Class); 

registerClassAlias("XML", XML);    
registerClassAlias("VecXML", Vector.<XML> as Class); 

registerClassAlias("myObjClass", myObjClass);    
registerClassAlias("VecMyObjClass", Vector.<myObjClass> as Class);

Trouble serializing vectors in a sub-class in AS3

4 Answers4