Ballerina annotation processing doesn't work as expected

Question

I am trying to implement a simple annotation processor with ballerina (jBallerina-1.0.5 on MacOS Catalina). In this example, I need to:

1. Iterate through available resource functions of a given service
2. For each iteration, get values of a given @annotation as annotated in the resource

For an example:

...
service my_service on new http:Listener(8080) {
    @my_annonatation {
        value: "my-value-for-resource-1"
    }
    resource function my_resource_1() {}

    @my_annonatation {
        value: "my-value-for-resource-2"
    }
    resource function my_resource_2() {}
}

According to the above service code snippet, I need get resource names as ["my_resource_1", "my_resource_2"] and @annotation value as my-value-for-resource-1,my-value-for-resource-2 for my_resource_1 and my_resource_2 accordingly.

My questions are:

1. How can I get the resources defined in a given service with ballerina
2. I have tried with function getServiceAnnotations(service serviceType, string annotName, string? moduleName = ()) returns any of ballerina/reflect module to get the @annotation value. But it doesn't give anything in return (Apparently it returns an empty string or could be null).

I don't see any good article for ballerina annotation processing, except for old ballerina 0.x pre-releases 1. I found that the ballerina/reflect module is now updated 2 3 since 0.x pre-releases as I compared with the ballerina source code (but it has not mentioned in ballerina release notes 4).

And also the article "Extending Ballerina" 5 has mentioned an alternative way for annotation processing through compiler extensions which delegates the operation to Java. However we have a limitation to push Java dependancies into the ballerina central.

Please suggest me a workaround to get the expected result and it is highly appreciated the code in pure ballerina language.

References

1. Ballerina Annotation Processing example for 0.9.x releases
2. ballerina/reflect of 0.x
3. ballerina/reflect of 1.0.5
4. Ballerina release notes
5. Extending Ballerina

Answer 1

Annotation processing can be done at either compile-time or runtime. Right now (with Ballerina 1.0.5 and earlier versions), compile-time annotation processing can only be done via the compiler extensions as described in the "Extending Ballerina" doc, whereas runtime annotation access can be done using the annotation access expression or via the ballerina/reflect module (only those that are not possible via the annotation access expression are now available in the ballerina/reflect module - while this addition is mentioned in the release notes "A binary operator .@ has been introduced to access annotation values at runtime.", the fact that this removes some functions from the ballerina/reflect module seems to have been missed).

https://github.com/ballerina-platform/ballerina-lang/issues/19325 describes the proposed Ballerina compiler plugin architecture, which would allow writing the extensions in Ballerina.

At runtime:

1. Retrieving the names of the resources defined in the service - IINM this is currently not possible without writing an external method (using Java interop). Are the names of the resources not known at compile time? Can you please create an issue in the ballerina-lang repository with the requirement?

2. Accessing the resource annotations - this can be done using the reflect:getResourceAnnotations method

import ballerina/http;
import ballerina/io;
import ballerina/reflect;

type AnnotRecord record {| 
    string value; 
|};

annotation AnnotRecord my_annonatation on resource function;

string[] resourceNames = ["my_resource_1", "my_resource_2"];

service my_service on new http:Listener(8080) {
    @my_annonatation {
        value: "my-value-for-resource-1"
    }
    resource function my_resource_1(http:Caller caller, http:Request request) {}

    @my_annonatation {
        value: "my-value-for-resource-2"
    }
    resource function my_resource_2(http:Caller caller, http:Request request) {}
}

public function main() {
    foreach var resourceName in resourceNames {
        any annot = reflect:getResourceAnnotations(my_service, resourceName, "my_annonatation");
        if annot is AnnotRecord {
            io:println(annot.value);
        }
    }
}

Answer 2

UPDATE:

@MaryamZis' solution is nicely worked for single ballerina files but not for ballerina projects. As she suggested, I have passed the <org-name>/<module>:<version> into the module parameter of the reflect:getResourceAnnotations function to get it working.

...
any annot = reflect:getResourceAnnotations(
    my_service, 
    resourceName, 
    "my_annonatation", 
    "my_org/my_module:0.1.0"
);
...

//NOTE: org-name and version are defined in Ballerina.toml of the project

However, it is expected to detect current projects' annotations by reflect functions without specifying the module. This issue is logged at the ballerina git repository by @MaryamZi.