Create custom standard output stream

Question

I am using LispWorks's Multiprocessing tools (see here). I start a number of subprocesses (using process-run-function), where each subprocess is associated with a particular mailbox. What I want to achieve is that messages to standard output (using format) in the subprocess end up in the mailbox, after which I can read them in the main process.

I would go about this by replacing the *standard-output* stream of the subprocess with a custom stream that calls mailbox-send on the formatted string. However, I have no idea on how to create a custom stream like this. What are my options here?

See also the documentation for User-defined Streams: http://www.lispworks.com/documentation/lw71/LW/html/lw-184.htm#pgfId-888202 — Rainer Joswig, Dec 12 '19 at 21:55

score 6 · Answer 1 · answered Dec 12 '19 at 17:08

Something like this:


(defclass mailbox-input-stream (stream:fundamental-character-input-stream)
  ((mailbox :initarg :mailbox
            :accessor mailbox-stream-mailbox
            :initform nil)))

(defmethod stream-element-type ((stream mailbox-input-stream))
  'character)

(defmethod stream:stream-read-char ((stream mailbox-input-stream))
  (let ((char (mp:mailbox-read (mailbox-stream-mailbox stream))))
    (if (eql char #\Line-Separator)
        #\Newline
        char)))

(defclass mailbox-output-stream (stream:fundamental-character-output-stream)
  ((mailbox :initarg :mailbox
            :accessor mailbox-stream-mailbox
            :initform nil)))

(defmethod stream-element-type ((stream mailbox-output-stream))
  'character)

(defmethod stream:stream-write-char ((stream mailbox-output-stream) char)
  (mp:mailbox-send (mailbox-stream-mailbox stream)
                   (if (eql char #\Newline)
                       #\Line-Separator
                       char)))

(defmethod stream:stream-line-column ((stream mailbox-output-stream))
  nil)

(defmethod stream:stream-start-line-p ((stream mailbox-output-stream))
  nil)

Then you can use READ-LINE, WRITE-LINE, READ-CHAR, WRITE-CHAR on streams created like this:

(make-instance 'mailbox-input-stream :mailbox (mp:process-mailbox process))

(make-instance 'mailbox-output-stream :mailbox other-mailbox)

Create custom standard output stream

1 Answers1