Is there a reason my AppleScript is running so slow?

Question

I have a script to run from a command line prompt. The command, followed by some text, will set a reminder in the Reminder.app with a due date of next friday. The script is taking about 100 seconds to run which seem very high.

on nextWeekday(wd)
    set today to current date
    set twd to weekday of today
    if twd is wd then
        set d to 7
    else
        set d to (7 + (wd - twd)) mod 7
    end if
    return today + (d * days)
end nextWeekday

on run argv
    set nextFriday to nextWeekday(Friday)
    tell application "Reminders"

        set newLable to argv as string

        set myList to list "Do."

        tell myList
            set newReminder to make new reminder
            set name of newReminder to newLable
            #set remind me date of newReminder to theDay
            set allday due date of newReminder to nextFriday
        end tell
    end tell
end run

The code in the .bash_profile is as follows:

function reme() {
  cd
  cd /Users/jamieauburn/Documents/projects/reminder
  osax reme.scpt $1
}

Have I got something wrong in the script?

Do you get the same long delay if Reminders is already open, or is part of this delay the launch time for that app? — Ted Wrigley, Nov 16 '19 at 19:28
have change is to `osascript`. Not quite sure what your mean @red_menace — JAuburn, Nov 19 '19 at 20:02

Robert Kniazidis · Answer 1 · 2021-09-27T06:43:49.300

0

You have a lot of unnecessary things here. Your script can be written much more compactly, and it becomes about 4 times faster.

on run argv
    tell (current date) to set nextFriday to it + (6 - (its weekday)) * days
    tell application "Reminders" to tell list "Do."
        make new reminder with properties {name:(argv as string), allday due date:nextFriday}
    end tell
end run

edited Sep 27 '21 at 06:43

answered Sep 27 '21 at 06:27

Robert Kniazidis

1,760
1
7
8

Is there a reason my AppleScript is running so slow?

1 Answers1