Timer in Action Script 3

Question

I have problem that I need to create timer but I want to pass on a variable to it, how to do it? Is it possible in AS3?

I tried like this:

            bonusPlayer1Timer = new Timer(5000);
            bonusPlayer1Timer.addEventListener(TimerEvent.TIMER, bonusChanges(player1));
            bonusPlayer1Timer.addEventListener(TimerEvent.TIMER_COMPLETE, bonusChangesRemove(player1));
            bonusPlayer1Timer.start();

function bonusChanges(event:TimerEvent, playerBonus:Player):void {
    switch (playerBonus.bonus) {
        case 0 :
            playerBonus.multipleShooting = false;
            playerBonus.bonus = -1;
            break;
...}}

But I have error:

1067: Implicit coercion of a value of type Player to an unrelated type flash.events:TimerEvent.
1136: Incorrect number of arguments.  Expected 2.

And this error is in the bold line.

Can I use it in this way? Or I have to create two the same function for every of my players because I am not allow to pass on any different arguments to the timer function?

Thank you,

score 8 · Accepted Answer · answered Apr 18 '11 at 01:33

Create a class that extends the Timer class and add a property for the Player.

public class PlayerTimer extends Timer
{
    public var thePlayer:Player;

    public function PlayerTimer(delay:Number, repeatCount:int=0)
    {
        super(delay, repeatCount);
    }       
}

Using your example the code would be something like this:

bonusPlayer1Timer = new PlayerTimer(5000);
bonusPlayer1Timer.thePlayer = new Player();
bonusPlayer1Timer.addEventListener(TimerEvent.TIMER, bonusChanges);
bonusPlayer1Timer.addEventListener(TimerEvent.TIMER_COMPLETE, bonusChangesRemove);
bonusPlayer1Timer.start();

function bonusChanges(event:TimerEvent):void {
    var playerBonus:Player = PlayerTimer(event.target).thePlayer; 
    switch (playerBonus.bonus) {
        case 0 :
            playerBonus.multipleShooting = false;
            playerBonus.bonus = -1;
            break;
...}}

Very nice mate just unlocked some knowledge for me there. Extend the class your interested in and allow it to attach a custom class. So event.target references the Timer object that has just triggered an event, right? — Alex, Apr 18 '11 at 04:24

score 2 · Answer 2 · answered Apr 18 '11 at 01:45

2

You can never pass more than one argument into the function triggered by an EventListener. You need to find other ways of passing your information around, such as the solution provided by Nathan Smith.

answered Apr 18 '11 at 01:45

Mark D

1,309
4
19
38

score 0 · Answer 3 · edited Nov 10 '12 at 22:19

0

you can also do it this way:

var x = setTimeout(yourfunction(/*arguments you need*/),1000);
function yourfunction(/*var*/){
    //your code
}

edited Nov 10 '12 at 22:19

Adi Lester

24,731
12
95
110

answered Nov 10 '12 at 21:58

Nicolas Sleiman

124
1
8

sry new in this blog got some problem with the comments thx to Adi lester – Nicolas Sleiman Nov 10 '12 at 22:24

score 0 · Answer 4 · answered Dec 23 '12 at 11:15

0

Just Type var bonusPlayer1Timer = new Timer(5000);

answered Dec 23 '12 at 11:15

Tareq Rahman

61
2

Timer in Action Script 3

4 Answers4