How do I override a Haskell package in nixpkgs via Nix?

Question

Essentially I'm using this:

default.nix

{ nixpkgs ? import <nixpkgs> {}, compiler ? "ghc864" }:
nixpkgs.pkgs.haskell.packages.${compiler}.callPackage ./gitchapter.nix { }

gitchapter.nix

{ mkDerivation, base, directory, extra, filepath, foldl, hpack
, HUnit, mtl, optparse-applicative, pandoc-include-code, parsec
, pretty-simple, process, QuickCheck, rainbow, regex-pcre
, regex-posix, safe, stdenv, string-conversions, system-filepath
, template-haskell, text, transformers, turtle, unix
, unordered-containers
}:
mkDerivation {
  pname = "gitchapter";
  version = "0.1.0.0";
  src = ./.;
  isLibrary = false;
  isExecutable = true;
  libraryToolDepends = [ hpack ];
  executableHaskellDepends = [
    base directory extra filepath foldl HUnit mtl optparse-applicative
    pandoc-include-code parsec pretty-simple process QuickCheck rainbow
    regex-pcre regex-posix safe string-conversions system-filepath
    template-haskell text transformers turtle unix unordered-containers
  ];
  preConfigure = "hpack";
  license = stdenv.lib.licenses.bsd3;
}

However there is an issue with the pandoc-include-code failing to build, which seems to have since been fixed in the git repository. How can I override the package either to point to git repository or a local directory?

Would I follow the instructions at https://nixos.org/nixos/nix-pills/nixpkgs-overriding-packages.html or would this work differently due to using the nixpkgs.pkgs.haskell.packages.${compiler}.callPackage function?

---

Edit: Thanks to @sara's answer I now have:

{ nixpkgs ? import <nixpkgs> {}, compiler ? "ghc864" } :
let
  gitchapter = nixpkgs.pkgs.haskell.packages.${compiler}.callCabal2nix "gitchaper" (./.) {};
  zzzzz = nixpkgs.pkgs.haskell.lib.overrideCabal gitchapter;
in
  nixpkgs.pkgs.haskell.packages.${compiler}.callPackage (zzzzz) { }

So it I suppose now it's a matter of determining how to override that dependency now.

Answer 1

Consider using callCabal2nix from haskell.packages.${compiler}!

It will go through your .cabal file and generate a nix expression for a derivation from that (thus making gitchapter.nix unnecessary), which you then can override using the overrideCabal function in haskell.lib in a similar fashion to normal derivation overriding. You can then fetch the updated pandoc derivation from git, and add it as a buildInput in your override expression.

Answer 2

Example of local path referenced:

{ nixpkgs ? import <nixpkgs> {}, compiler ? "ghc864" } :
let
  myHaskellPackages = nixpkgs.pkgs.haskell.packages.${compiler}.override {
    overrides = self: super: rec {
    pandoc-include-code  = self.callCabal2nix "pandoc-include-code" (./pandoc-include-code) {};
    };
  };
in
  myHaskellPackages.callCabal2nix "gitchaper" (./.) {}

Other alternatives:

Git repo:

    pandoc-include-code  = self.callCabal2nix "pandoc-include-code" (builtins.fetchGit {
        url = "git@github.com:owickstrom/pandoc-include-code.git";
        rev = "3afe94299b3a473fda0c62fdfd318435117751dd";
      })
      {};

Hackage (via tar archive) example:

  prettyprinter = self.callCabal2nix "prettyprinter" (builtins.fetchTarball {
    url = "https://hackage.haskell.org/package/prettyprinter-1.7.0/prettyprinter-1.7.0.tar.gz";
  }) {};