2

edit: you can follow the progress here: https://github.com/simple-updates/template

I'm using peg.js and trying to write something that could interpret a template like:

hello {{ "world" }}
{% if a %}
  good {{ a }}
{% else %}
  bad
{% endif %}

I've tried many things but let's say this is my starting point:

Template
  = ws markup ws

ws = " "*

open_interpolation = "{{"
close_interpolation = "}}"
open_tag = "{%"
close_tag = "%}"

char = . // ?

markup =
  (open_tag tag:char* close_tag)
  { return { 'tag': tag.join('') } } /
  (open_interpolation interpolation:char* close_interpolation)
  { return { 'interpolation': interpolation.join('') } } /
  chars:char*
  { return { 'chars': chars.join('') } }

when I try on the string {{ test }} for instance it will just interpret it as chars instead of an interpolation.

any idea of how I could do it?

(obviously it would be more complex with nested "markups")

localhostdotdev
  • 1,795
  • 16
  • 21

2 Answers2

1

How about something like this as a start:

Template
 = Atom*

Atom
 = IfTag
 / Interpolation
 / [^{]
 / !"{%" !"{{" "{"

Interpolation
 = "{{" _ Expression _ "}}"

IfTag
 = If Template ( Else Template )? EndIf

If
 = "{%" _ "if" _ Expression _ "%}"

Else
 = "{%" _ "else" _ "%}"

EndIf
 = "{%" _ "endif" _ "%}"

Expression
 = "\"" [^"]* "\""
 / [a-zA-Z]+
 / [0-9]+

_
 = [ \t\n\r]*

The tricky part here is the !"{%" !"{{" "{" alternative of the Atom production, which reads as follows:

When no "{%" and "{{" can be seen ahead of the current position, match a single "{"

Bart Kiers
  • 166,582
  • 36
  • 299
  • 288
  • thanks, I will definitely reuse some of your ideas (_ for whitespace and `[^{] / !"{%" !"{{" "{"` in particular).if you want to follow the progress, the parser is an almost completely done: https://github.com/simple-updates/template (template.pegjs file) – localhostdotdev May 14 '19 at 22:13
  • tried it and thinking about it i'm really not sure what's the difference with `(!"{{" !"{%" .)` – localhostdotdev May 15 '19 at 09:09
  • There's (probably) no difference between `!"{{" !"{%" .` and `[^{] / !"{%" !"{{" "{"`. But with the latter, it is more clear to me what is happening. And I also suspect that the generated parser for the latter will be (a bit) better performing since it will need much less look-aheads than `!"{{" !"{%" .` – Bart Kiers May 15 '19 at 17:58
0

ok I'm not at the nested part of anything much yet but I got my tags/interpolations working

the key is those !not_something value

current grammar:

{
    function j(value) {
        return value.join('')
    }
}

Template
  = ws markup:markup ws { return markup }

ws = " "*

open_interpolation = "{{"
close_interpolation = "}}"
open_tag = "{%"
close_tag = "%}"

value = .

not_close_interpolation =
    ws !close_interpolation value:value ws { return value }

not_close_tag =
    ws !close_tag value:value ws { return value }

not_open_tag_or_interpolation =
    !open_interpolation !open_tag value:value { return value }

markup =
    (
      open_interpolation interpolation:not_close_interpolation+ close_interpolation {
          return { 'interpolation': j(interpolation) }
      } /
      open_tag tag:not_close_tag+ close_tag {
          return { 'tag': j(tag) }
      } /
      value:not_open_tag_or_interpolation+ { return j(value) }
    )+
localhostdotdev
  • 1,795
  • 16
  • 21