Answer Set Programming: Re-arrange matrix so that in no row 2 numbers are in the same order

Question

Let's I have matrix

A =

1 2 3

1 3 5

1 2 4

2 3 7

The task is to re-arrange the matrix so that in no row two elements are in the same order.

For example, in row 1 and row 2 we have numbers 1 and 3 in the same order. We flip the numbers in 1 and 3 left to right in row 1 and get

3 2 1

1 3 5

1 2 4

2 3 7

My thoughts are this is a search problem, that could be maybe solved with Answer Set Programming? The problem is that if you try to do this with some algorithm, at some point you end up putting two numbers in to the same order as they are in some other row.

This is useful for reorienting triangular surface mesh faces of a mesh where the face normals point to inconsistent directions so that all normals point to inward (or outward)

Answer 1

Yes you can do this with ASP.

This is not the most elegant code but I think you could do it like this if you use Clingo series 5:

%% List the numbers to fill the matrix, we must associated each with an index value
number(1,1;2,2;3,3;1,4;3,5;5,6;1,7;2,8;4,9;2,10;3,11;7,12).

%% x limits
x(0..2).

%% y limits
y(0..3).

%% Generate the matrix
{ matrix(V, I, X, Y) } :- number(V, I), x(X), y(Y).

%% Define the order of the elements
order(V1, I1, V2, I2, Y) :- matrix(V1, I1, X1, Y), matrix(V2, I2, X2, Y), X1 < X2.

%% Do not allow two different rows to have the same order of elements
:- order(V1, I1, V2, I2, Y1), order(V1, I3, V2, I4, Y2), Y1 != Y2.

%% Each number must be in the matrix exactly once
:- not { matrix(V, I, X, Y) } = 1, number(V, I).

%% Each element can contain only one number
:- not #count { V, I : matrix(V, I, X, Y) } = 1, matrix(_, _, X, Y).

%% Show the matrix
#show matrix/4.

Which gives you this as output:

3 1 3

4 2 3

1 1 5

2 2 7

Although bare in mind there are many hundreds of thousands (I think millions) of ways to order this matrix and get a result which satisfies your constraints.

Answer 2

Given input in the form:

value(ROW,COL,VAL).
nrows(nr).
ncols(nc).

You can do something like:

row(1..NR) :- nrows(NR).
col(1..NC) :- ncols(NC).
is_value(V) :- value(_, _, V).

% For each position in the original matrix, say what new column it's in.
{new_place(ROW,OLDCOL,NEWCOL,VAL) : col(NEWCOL)} = 1 :- value(ROW,OLDCOL,VAL).
% Can't have more than one value in the same position.
:- {new_place(ROW,_,COL,_)} > 1; row(ROW); col(COL).
% A comes before B in row ROW if COL_A < COL_B
ordered(A,B,ROW) :- new_place(ROW,_,COL_A,A); new_place(ROW,_,COL_B,B); COL_A < COL_B.
% For any two values A and B, there exists at most one row where A comes before B
:- {ordered(A,B,ROW) : row(ROW)} > 1; is_value(A); is_value(B).

#show.
#show p(R,C,V) : new_place(R,_,C,V).

Note that you have to keep track of the original column in case there are duplicates within a row. If no row contains duplicates (as is the case in your example) the second parameter of new_place is unnecessary.