How to get the Wikidata labels for approximate terms?

Question

I am using the below mentioned query to obtain the wikidata lable for a given term.

SELECT ?item WHERE {
  ?item rdfs:label "Word2vec"@en
}

The output is wd:Q22673982

However, when I spell Word2vec as word2vec (i.e. all characters are simple letters) I get "No results" from the above query.

Therefore, I would like to know if there is a way to get how the term is in wikidata and get its label?

i.e. if I enter with all characters lower cased, how to identify the equivalent wikidata term and return its corresponding label?

Answer 1

The comments by AKSW are a better solution that the accepted answer, but since AKSW is not in the habit of posting proper answers, I'll do it for him...

We don't know your use-case, but if you're just trying to make a simple search in Wikidata entities, other services, such as the MediaWiki API entity search might be more efficient. You can even use it inside SPARQL, e.g.:

SELECT * {
    SERVICE wikibase:mwapi {
        bd:serviceParam wikibase:api "EntitySearch".
        bd:serviceParam wikibase:endpoint "www.wikidata.org".
        bd:serviceParam mwapi:search "word2vec".
        bd:serviceParam mwapi:language "en".
        ?item wikibase:apiOutputItem mwapi:item.
        ?num wikibase:apiOrdinal true.
    }
    ?item (wdt:P279|wdt:P31) ?type
}
ORDER BY ?num
LIMIT 20

Run this query live

What's going on in this query?

1. The SERVICE call to wikibase:mwapi is not standard SPARQL, but a SPARQL extension that calls the Mediawiki API, in particular its entity search. More about that in the manual. What matters is the search term as value to mwapi:search, and the two lines that bind the found item to the variable ?item, and its rank in the search results to ?num.
2. The line ?item (wdt:P279|wdt:P31) ?type binds the type of each item to the variable ?type. It takes into account both the “subclass of” and “instance of” properties.
3. ORDER BY ?num makes sure that the results are ordered by the rank, that is, the best match comes first, the second best match second, etc.
4. LIMIT 20 keeps only the first 20 results in case there are more than 20.
5. SELECT * means return all variables that were bound in the query, so in this case it will be ?item, ?type and ?num.

Extending it for multiple search terms

As per comments, this can be extended to run for multiple search terms:

SELECT * {
    VALUES ?searchTerm { "word2vec" "fasttext" "natural language processing" "deep learning" "support vector machine" }
    SERVICE wikibase:mwapi {
        bd:serviceParam wikibase:api "EntitySearch".
        bd:serviceParam wikibase:endpoint "www.wikidata.org".
        bd:serviceParam wikibase:limit 10 .
        bd:serviceParam mwapi:search ?searchTerm.
        bd:serviceParam mwapi:language "en".
        ?item wikibase:apiOutputItem mwapi:item.
        ?num wikibase:apiOrdinal true.
    }
    ?item (wdt:P279|wdt:P31) ?type
}
ORDER BY ?searchTerm ?num

Run this query live

• The search terms are provided in a VALUES clause and bound to the ?searchTerm variable
• That variable is then used in the service call
• The LIMIT 20 now no longer works because it would limit the total number of results instead of just for one term, so I removed it
• Instead, added wikibase:limit to the service parameters
• Changed the ordering so that it first orders by search term and then by rank

Answer 2

If you're unsure of the precise spelling or capitalisation, you can use a filter function to perform the match. For example, to match regardless of capitalisation, you could use the LCASE() (or UCASE()) function, as follows:

SELECT ?item WHERE {
  ?item rdfs:label ?label
  FILTER(LCASE(STR(?label)) = "word2vec")
}

This transforms any found label to lower-case and the compares to the lower-case string.

There's a whole host of different functions you can use for string manipulation, there's good overview in the SPARQL 1.1 W3C Recommendation.

NOTE doing this kind of query is significantly more expensive (in terms of execution time), because the engine will have to do a sequential scan over all possible matches. Like @AKSW mentioned in the commments, the query as-is is likely to time out when you execute it on the Wikidata public endpoint. It would probably help a lot if you made the query more specific by adding additional triple patterns.

Update If you have a look at the information available for wd:Q22673982 (you can browse it at https://www.wikidata.org/wiki/Q22673982 ) you'll see that, among other things, it's a subclass of "word embeddding" (wd:Q18395344). So what you could do for example, instead of just asking for every ?item that has a rdfs:label, is ask for all items that are a subclass of wd:Q18395344 and have this label, like this:

SELECT DISTINCT ?item WHERE {
  ?item wdt:P279 wd:Q18395344;
        rdfs:label ?label
  FILTER(LCASE(STR(?label)) = "word2vec")
}

Unfortunately, Wikidata uses rather cryptic identifiers for its properties and relations. Suffice to say that wdt:P279 corresponds to the "subclass" relation. The DISTINCT was something I added because otherwise you get the same answer 10 or more times.