Why does this fish while loop terminate after a single iteration?

Question

This is a fish function used to upgrade JavaScript packages for a project. Strangely, it terminates after a single iteration with an exit status of 0. Why?

function yarn-upgrade-all --description "Upgrade JavaScript packages"
    yarn outdated | sed '1,/^Package/d;/^Done/d' | awk '{print $1, $4}' | while read -l PACKAGE VERSION
        echo
        set_color brwhite
        echo -n "==>"
        set_color yellow
        echo -n " "$PACKAGE
        set_color brblue
        echo -n " "$VERSION
        set_color brwhite
        echo -n " <=="
        set_color normal
        echo
        echo

        yarn upgrade --latest $PACKAGE
        and yarn run test
        and yarn run build
        and git commit -am "Upgrade to "$PACKAGE" "$VERSION
        or begin
            set_color red
            echo "last command exited with status $status" >&2
            set_color normal
            return 1
        end
    end
end

On the other hand, this second function, which contains only a stub body, runs through all packages piped into the loop.

function yarn-upgrade-all-debug --description "Upgrade JavaScript packages"
    yarn outdated | sed '1,/^Package/d;/^Done/d' | awk '{print $1, $4}' | while read -l PACKAGE VERSION
        echo $PACKAGE $VERSION
    end
end

fish --version

fish, version 3.0.2

Does one of those `yarn` commands, or the `git` command, slurp up the rest of the stdin? — glenn jackman, Apr 18 '19 at 19:17
@glennjackman You're right. Redirecting stdin to /dev/null for the commands in the loop body fixes it. Would you like to add your comment as an answer? — Claudio, Apr 19 '19 at 14:30

score 2 · Answer 1 · answered Apr 18 '19 at 18:35

2

You're running fish 3.0.0, and hitting https://github.com/fish-shell/fish-shell/issues/5513 - return from a while doesn't actually set the status correctly.

However, the return still causes it to terminate the while-loop.

Upgrade to 3.0.2.

answered Apr 18 '19 at 18:35

faho

14,470
2
37
47

Thanks, but I'm already running fish 3.0.2. Updated the question with the fish version. – Claudio Apr 18 '19 at 18:38

Claudio · Accepted Answer · 2019-04-22T08:50:45.697

The loop terminates after a single iteration because the yarn run invocations in the loop body slurp up the rest of stdin. (Credits to @glenn-jackman.)

A possible workaround is to redirect stdin to /dev/null for these commands:

        and yarn run test < /dev/null
        and yarn run build < /dev/null

The culprit is run-s from the npm-run-all package, which is invoked by both yarn run commands.

https://github.com/mysticatea/npm-run-all/issues/166

Why does this fish while loop terminate after a single iteration?

2 Answers2