How to check if file exist and ask to overwrite in Pascal Script code

Question

function CreateLICStopServiceBatch(): boolean;
  begin
    Result := true;
    fileName := ExpandConstant('{code:GetBasicDirectoryValue}\{code:GetInstance}\_Service\Stop_LIC_Service.bat');
    SetArrayLength(lines, 3);
    lines[0] := ExpandConstant('set wrapdir={code:GetBasicDirectoryValue}\{code:GetInstance}\_Service');
    lines[1] := 'cd /d %wrapdir%';
    lines[2] := ExpandConstant('commons-daemon\prunsrv.exe //SS//{code:GetLSDVBServiceNameTEdit}');
    Result := SaveStringsToFile(filename,lines,false);
    exit;
  end;

CreateLICStopServiceBatch();

Right now I'm just writing the file in to the directory, doesn't matter if the file exist or not. But I want to check if the file exist (FileExists) and also have the opportunity to choose (in a dialog) overwrite or take the old file which already exist.

Answer 1

• Use FileExists function to test for file existence.
  See Inno Setup - Check if file exist in destination or else if doesn't abort the installation
• Use MsgBox function for confirmation.
  See Inno Setup: Conditionally delete non-empty directory in user's home folder
• Side note: Do not use ExpandConstant('{code:Function}') is Pascal code. That makes no sense. Call Function directly. Not to mention that your functions probably do something trivial, which you can inline to your code anyway.

function CreateLICStopServiceBatch(): boolean;
var
  FileName: string;
  Lines: TArrayOfString;
begin
  FileName := GetBasicDirectoryValue + '\' + GetInstance + '\_Service\Stop_LIC_Service.bat';
  SetArrayLength(Lines, 3);
  Lines[0] := 'set wrapdir=' + GetBasicDirectoryValue + '\' + GetInstance + '\_Service';
  Lines[1] := 'cd /d %wrapdir%';
  Lines[2] := 'commons-daemon\prunsrv.exe //SS//' + GetLSDVBServiceNameTEdit;

  if (not FileExists(FileName)) or
     (MsgBox('Overwrite?', mbConfirmation, MB_YESNO) = idYes) then
  begin
    Result := SaveStringsToFile(FileName, Lines, False);
  end
    else
  begin
    { Not sure what you want to return when user does not confirm overwrite }
    Result := False;
  end;
end;