How to get TableName of a DataSet?

Question

How do I get the TableName of a DataSet?

I tried this:

var
  Tblname: string;
begin
  Tblname := DBGrid1.DataSource.DataSet.TableName;
  //it is not working
  //DataSet.TableName is protected
end;

Use RTTI. I'll add an example in a few minutes or so. I had a similar problem using NexusDB instead of TTable. It had all similar properties (jkndexname, tablename etc) but was not derived from TTable — H.Hasenack, Feb 05 '19 at 21:22
TDataset descendants do not necessarily have a meaningful TableName, so what you ask is impossible in the general case. What specific type of TDataSet descendant are you using? And are you asking about the table name in the back-end RDMS? — MartynA, Feb 05 '19 at 22:23
Do you always use the same component, for example TADOTable ? In that case its as simple as `(DBGrid1.DataSource.DataSet as TADOTable).TableName` — GuidoG, Feb 07 '19 at 10:09

H.Hasenack · Answer 1 · 2019-02-06T09:28:57.187

2

Using RTTI it is possible to get the value for any property. The example below returns the value of the TableName property, provided there is one. I have verified that the code works in a small project.

The main benefit would be that it works on any TDataset derived class that has a TableName property. (eg TTable, but also TSQLTable or TFDTable)

....
uses DB,rtti;

function GetTableNameFromDataset(aDataset:TDataset):string;
VAR lTableNameProp:TRttiProperty;
    lContext:TRttiContext;
begin
  Result:='';
  if Assigned(aDataset) then 
  begin
    lContext.Create;
    try
      lTableNameProp:=lContext.GetType(aDataset.ClassInfo).GetProperty('TableName');
      if Assigned(lTableNameProp) then
        Result:=lTableNameProp.GetValue(aDataset).AsString;
    finally
      lContext.Free;
    end;
  end;
end;
....

Or an alternate solution using the old-style typinfo module (tested on RS 10.3, but I expect it to work on D7 as well)

... 
uses DB,typinfo;

function GetTableNameFromDataset(aDataset:TDataset):string;
VAR lPropInfo:PpropInfo;
begin
  Result:='';
  if Assigned(aDataset) then
  begin
    lPropInfo:=GetPropInfo(aDataset.ClassInfo,'TableName');
    if Assigned(lPropInfo) then
      Result:=GetPropValue(aDataset,lPropInfo);
  end;
end;   
...

edited Feb 06 '19 at 09:28

answered Feb 05 '19 at 21:33

H.Hasenack

1,094
8
27

3

The use of `with Txxx.Create` is an abomination that Delphi ought not permit, imo. – MartynA Feb 05 '19 at 22:29
Sure, bit it's still a working example. It's not about the with statement, but about how you can get a tablename from a dataset. Changing the TrttiContext into a local variable is easy, I updated the code (untested) – H.Hasenack Feb 06 '19 at 07:45
File Not found 'Rtti.dcu' – Djemoui Feb 06 '19 at 08:52
Used version Delphi 7 – Djemoui Feb 06 '19 at 09:12
Okay, If I find the time I'll add the solution for older delphi releases (using the typinfo unit rathrer than the rtti unit) (I'm at work, anbd the example is at home) – H.Hasenack Feb 06 '19 at 09:14
Used version Delphi 7 – Djemoui Feb 06 '19 at 09:17
Yes, I took some minutes at work to find solution using typinfo, and verified it works. – H.Hasenack Feb 06 '19 at 09:30
Result:=GetPropValue(aDataset,lPropInfo); Error Incompatible types:'string' and 'PPropInfo' – Djemoui Feb 06 '19 at 13:32
1

Change `GetPropValue()` to `GetStrProp()` instead: `Result := GetStrProp(aDataset, lPropInfo);` – Remy Lebeau Feb 06 '19 at 17:22
Thanks me changer TADOTable To TADOQUERY Result:=Nil How To use this fonction a TTable, TQuery, TadoTable, TadoQuery, Tcommand, TFDTable, TFDQuery..etc – Djemoui Feb 06 '19 at 18:26
@Remy, thx/ Obviously some differences between D7 and RS10.3, which supports overloading and D7 does not. – H.Hasenack Feb 06 '19 at 22:01
3

@Djemoui non-table components simply don't have a `TableName` property. – Remy Lebeau Feb 06 '19 at 22:34
In your second solution, `Result:=GetPropValue(aDataset,lPropInfo);` has to be `Result := GetPropValue(aDataset, lPropInfo.Name);` and then this will work in Delphi 7 – GuidoG Feb 07 '19 at 10:36
@GuidoG Thx, (I don't have D7 up and running here) – H.Hasenack Feb 07 '19 at 10:42
no problem, I still have one here and it only took a minute to test it... – GuidoG Feb 07 '19 at 10:43

How to get TableName of a DataSet?

1 Answers1