apache nifi - split line of json by field value

Question

In Apache Nifi, i want to split a line of a json file based on the content of a field delemited by comma.

This is an example of my input flowfile :

{
    "name":"app",
    "os":"linux",
    "instance":"instance1,instance2,instance3,instance4"
}

And this is want as output :

{
    "name":"app",
    "os":"linux",
    "instance":"instance1"
},
{
    "name":"app",
    "os":"linux",
    "instance":"instance2"
},
{
    "name":"app",
    "os":"linux",
    "instance":"instance3"
},
{
    "name":"app",
    "os":"linux",
    "instance":"instance4"
}

I need to know if it's possible to realise this task with the joltTransformJson processor or if i must do that with a script, in this case can you please show some similar examples scripts.

Thanks

daggett · Accepted Answer · 2018-11-30T19:14:59.850

don't know about jolt.

with ExecuteGroovyProcessor you can do this transformation in a following way:

import groovy.json.*

def ff=session.get()
if(!ff)return
//read stream, convert to reader, parse to objects
def json=ff.read().withReader("UTF-8"){r-> new JsonSlurper().parse(r) }
//transform json
json = json.instance.split(',').collect{e-> json+[instance:e] }
//write
ff.write("UTF-8"){w-> new JsonBuilder(json).writeTo(w)}
//transfer to success
REL_SUCCESS<<ff

The same but for ExecuteScript processor:

import groovy.json.*

def ff=session.get()
if(!ff)return

ff = session.write(ff, {inputStream, outputStream ->
    def json=inputStream.withReader("UTF-8"){r-> new JsonSlurper().parse(r) }
    json = json.instance.split(',').collect{e-> json+[instance:e] }
    outputStream.withWriter("UTF-8"){w-> new JsonBuilder(json).writeTo(w)}
} as StreamCallback)

session.transfer(ff, REL_SUCCESS)

Thanks for the answer @daggett , I tested this script on the executeScript processor (because i'm using Nifi 1.2 and it doesn't work, do you think it is possible to do it on Nifi 1.2? — yacine klm, Nov 30 '18 at 18:34
for nifi 1.2 should be reworked just a little.. i'll update the answer — daggett, Nov 30 '18 at 19:07

apache nifi - split line of json by field value

1 Answers1