Unambiguous grammar for expressions with let and addition

Question

What is an unambiguous grammar equivalent to to the following ambiguous grammar for a language of expressions with let and addition?

E ⇒ let id = E in E

E ⇒ E + E

E ⇒ num

The ambiguity should be solved so that:

addition is left associative
addition has higher precedence than let expressions when it appears on the right
addition has lower precedence than let expressions when it appears on the left

Using braces to show the grouping of sub-expressions, the following illustrates how expressions should be interpreted:

num + num + num => { num + num } + num

let id = num in num + num => let id = num in { num + num }

num + let id = num in num => num + { let id = num in num }

score 2 · Answer 1 · answered Nov 05 '18 at 17:40

Consider the expression

E₁ + E₂

E₁ cannot have the form let ID = E₃ because let ID = E₃ + E₂ must be parsed as let ID = (E₃ + E₂). This restriction is recursive: it also cannot have the form E₄ + let ID = E₃.

E₂ can have the form let ID = E₃ but it cannot have the form E₃ + E₄ (because E₁ + E₃ + E₄ must be parsed as (E₁ + E₃) + E₄). Only E₁ can have the form E₃ + E₄.

It's straight-forward (but repetitive) to translate these restrictions to BNF:

Expr      ⇒ Sum

Sum       ⇒ SumNoLet '+' Atom
          | Atom
SumNoLet  ⇒ SumNoLet '+' AtomNoLet
          | AtomNoLet

AtomNoLet ⇒ num
          | id
          | '(' Expr ')'
Atom      ⇒ AtomNoLet
          | 'let' id '=' Expr

To make the pattern clearer, we can add the * operator:

Expr      ⇒ Sum

Sum       ⇒ SumNoLet '+' Prod
          | Prod
SumNoLet  ⇒ SumNoLet '+' ProdNoLet
          | ProdNoLet

Prod      ⇒ ProdNoLet '*' Atom
          | Atom
ProdNoLet ⇒ ProdNoLet '*' AtomNoLet
          | AtomNoLet

AtomNoLet ⇒ num
          | id
          | '(' Expr ')'
Atom      ⇒ AtomNoLet
          | 'let' id '=' Expr

It is possible to implement this in bison (or other similar parser generators) using precedence declarations. But the precedence solution is harder to reason about, and can be confusing to incorporate into more complicated grammars.

Unambiguous grammar for expressions with let and addition

1 Answers1