Calculate total and subtotal without loop?

Question

I am starting learning the new abap. But i have problems. I want to make result output as below without using "LOOP" and "AT" statements.

I have internal table like:

Category Amount
    AAA     10
    AAA     20
    BBB     30
    CCC     40
    CCC     50
    CCC     60

I need to display output as:

Category Amount
    AAA       10
    AAA       20
    SUBTOTAL  30
    BBB       30
    SUBTOTAL  30
    CCC       40
    CCC       50
    CCC       60
    SUBTOTAL  150
    TOTAL     210

Can anyone help with this?

Could you please share what you tried, and explain exactly where you're stuck? — Sandra Rossi, Oct 10 '18 at 11:58
Related question with a simplified version of this problem: [Get total without LOOP in abap](https://stackoverflow.com/questions/62753905/get-total-without-loop-in-abap) — Philipp, Jul 06 '20 at 15:14

Sandra Rossi · Accepted Answer · 2018-10-12T12:53:13.447

If your question is about how to build an internal table (in memory) with constructor expressions (ABAP >= 7.40), rather than rendering it on the screen or in a spool file (totals and subtotals are features well integrated in ALV and easy to use), then here's one way to do it (ASSERT is here to show that the final value is as expected) :

TYPES : BEGIN OF ty_line,
          category TYPE string,
          amount   TYPE decfloat16,
        END OF ty_line,
        ty_lines TYPE STANDARD TABLE OF ty_line WITH DEFAULT KEY.

DATA(gt_main) = VALUE ty_lines( ( category = 'AAA' amount = 10 )
                                ( category = 'AAA' amount = 20 )
                                ( category = 'BBB' amount = 30 )
                                ( category = 'CCC' amount = 40 )
                                ( category = 'CCC' amount = 50 )
                                ( category = 'CCC' amount = 60 ) ).

DATA(lt_display) = VALUE ty_lines(
        ( LINES OF VALUE #(
              FOR GROUPS <g> OF <line> IN gt_main
              GROUP BY ( category = <line>-category )
              ( LINES OF VALUE #( FOR <line2> IN GROUP <g> ( <line2> ) ) )
              ( category = 'SUBTOTAL'
                amount = REDUCE #( INIT subtotal TYPE ty_line-amount
                                   FOR <line2> IN GROUP <g>
                                   NEXT subtotal = subtotal + <line2>-amount ) ) ) )
        ( category = 'TOTAL'
          amount = REDUCE #( INIT total TYPE ty_line-amount
                             FOR <line> IN gt_main
                             NEXT total = total + <line>-amount ) ) ).

ASSERT lt_display = VALUE ty_lines( ( category = 'AAA'      amount = 10 )
                                    ( category = 'AAA'      amount = 20 )
                                    ( category = 'SUBTOTAL' amount = 30 )
                                    ( category = 'BBB'      amount = 30 )
                                    ( category = 'SUBTOTAL' amount = 30 )
                                    ( category = 'CCC'      amount = 40 )
                                    ( category = 'CCC'      amount = 50 )
                                    ( category = 'CCC'      amount = 60 )
                                    ( category = 'SUBTOTAL' amount = 150 )
                                    ( category = 'TOTAL'    amount = 210 ) ).

Joey · Answer 2 · 2018-10-11T09:54:07.027

I make this code as below.

TYPES: LTY_DISPLAY TYPE STANDARD TABLE OF TY_DISPLAY WITH EMPTY KEY.

LT_DISPLAY = REDUCE LTY_DISPLAY
             ( INIT LIST = VALUE LTY_DISPLAY( )
               SUBTOTAL = VALUE LTY_DISPLAY( )
               TOTAL = VALUE LTY_DISPLAY( )
               LV_TEXT TYPE STRING

               FOR GROUPS <GROUP_KEY> OF <WA> IN GT_MAIN GROUP BY ( CATEGORY = <WA>-CATEGORY ) ASCENDING
               NEXT lV_TEXT = <GROUP_KEY>
                    LIST = VALUE LTY_COSP( BASE SUBTOTAL FOR <WA1> IN GROUP <GROUP_KEY> ( <WA1> ) )
                    SUBTOTAL = VALUE LTY_COSP( BASE LIST ( CATEGORY = 'SUBTOTAL' && LV_TEXT
                                                           AMOUNT = REDUCE #( INIT SUM TYPE P
                                                                               FOR M IN GROUP <GROUP_KEY>
                                                                               NEXT SUM = SUM + M-AMOUNT ) ) )
                    TOTAL = VALUE LTY_COSP( BASE SUBTOTAL ( CATEGORY = 'TOTAL' 
                                                              AMOUNT = REDUCE #( INIT SUM TYPE P
                                                                                  FOR M IN GT_MAIN
                                                                                  NEXT SUM = SUM + M-AMOUNT ) ) ) ).

Bilal Saleem · Answer 3 · 2018-10-10T23:29:33.713

0

If you don't want to loop through the internal table using loop at, then you can always use a function module that will go through the internal table for you and print the totals and subtotals.

REUSE_ALV_GRID_DISPLAY is one such function module.

You can check the following link for a tutorial: http://www.saphub.com/abap-tutorial/abap-alv-total-subtotal/

The above is implemented in a procedural programming paradigm and is newer than original way of making reports in SAP (where you would use print statements).

However, an even newer way than that would to use the object-oriented implementation of ALV reports. Look into CL_GUI_ALV_GRID.

Here is an introductory article on CL_GUI_ALV_GRID: https://wiki.scn.sap.com/wiki/display/ABAP/OBJECT+ORIENTED+ALV+Guide

edited Oct 10 '18 at 23:29

answered Oct 10 '18 at 21:53

Bilal Saleem

633
4
8

Although the answer makes sense in the real world (ALV calculate/display the totals and subtotals), the question is more about solving with **ABAP constructor expressions** rather than displaying the expected result (if I interpret well "learning the new ABAP", "without LOOP" of course). – Sandra Rossi Oct 11 '18 at 20:16
1

@SandraRossi but then you skip the other half of the question: "want to make result output as below". Having the data in an internal table will not create any output. – Gert Beukema Oct 11 '18 at 21:21
@GertBeukema right, so I updated my answer to say that I cover one aspect of the question, not the ALV solution – Sandra Rossi Oct 12 '18 at 06:23

Calculate total and subtotal without loop?

3 Answers3

Linked