How to insert separators between columns?

Question

I have columns in @columns:

my @columns =('column1', 'column2', 'column3');

and I have separators in @separators:

my @separators = (',', '|');

I want to insert the separators between columns, one by one:

column1,column2|column

my solution is:

(@columns »~» (|@separators,"")).join("")

Here I have three columns and two separators, and how about insert N-1 separators between N columns?

You could try `say ((@columns Z @separators), @columns[*-1]).flat.join("")` — Håkon Hægland, Jul 26 '18 at 16:07
Do mean the case that `N` is different from `@columns.elems`? — Håkon Hægland, Jul 26 '18 at 16:18
@HåkonHægland `N` is equal to `@columns.elems`, also equal to `@separators.elems +1 ` — chenyf, Jul 26 '18 at 16:29
But doesn't your proposed solution already work fine for that case? — Håkon Hægland, Jul 26 '18 at 16:38
`(@columns >>,>> @separators).map( |* )[0..*-2].join("")` This works for any number of columns I think. — Scimon Proctor, Jul 26 '18 at 16:41
`@columns.reduce: { $^a ~ @separators[$++] ~ $^b};` or `@separators.push: ""; say [~] @columns Z~ @separators;` — wamba, Jul 26 '18 at 16:48

score 9 · Accepted Answer · edited Jun 20 '20 at 09:12

9

Assuming that @separators has the right number of values, you could use roundrobin.

roundrobin( @columns, @separators ).flat.join()

edited Jun 20 '20 at 09:12

Community

1
1

answered Jul 26 '18 at 17:14

Brad Gilbert

33,846
11
78
129

Scimon Proctor · Answer 2 · 2018-07-27T08:04:48.917

So this should work for a any length of @columns or @separators :

First we use the >>,>> hyper operator to make a list of lists.

(@columns >>,>> @separators)

Which gives :

[("column1", ","), ("column2", "|"), ("column3", ",")]

Then we flatten this into a single list using a slip.

(@columns >>,>> @separators).map( |* )

Which gives:

("column1", ",", "column2", "|", "column3", ",").Seq

Then we get the array of all but the last value :

(@columns >>,>> @separators).map(|*).head(*-1)

For :

("column1", ",", "column2", "|", "column3")

And finally join it with nothing :

(@columns >>,>> @separators).map(|*).head(*-1).join("")

Final result :

column1,column2|column3

Changing the number of columns or separators will not make a difference.

I think `[^(*-1)]` would be clearer if written as `.head(*-1)` — Brad Gilbert, Jul 26 '18 at 19:19

score 0 · Answer 3 · answered Dec 17 '18 at 06:48

May be another solution:

my @columns =('column1', 'column2', 'column3');
my @separators = (',', '|');
sub sep { $^a ~@separators[$++] ~$^b};
say [[&sep]] @columns;

say [[&sep]] @columns; # but another call cause error


Use of uninitialized value of type Any in string context.
Methods .^name, .perl, .gist, or .say can be used to stringify it to something     meaningful.
in sub sep at <unknown file> line 1
in block <unit> at <unknown file> line 1

Use of uninitialized value of type Any in string context.
Methods .^name, .perl, .gist, or .say can be used to stringify it to something  meaningful.
in sub sep at <unknown file> line 1
in block <unit> at <unknown file> line 1

column1column2column3

How to insert separators between columns?

3 Answers3