Servant QueryParams parse error

Question

Given the following code:

newtype HelloMessage = HelloMessage { msg :: String }
  deriving (Generic)

instance ToJSON HelloMessage

type API2 = "hello"
            :> QueryParam "age" Int
            :> Get '[JSON] HelloMessage

appAPI2 :: Proxy API2
appAPI2 = Proxy

myHandler :: Server API2
myHandler = helloHandler
  where
    helloHandler :: Maybe Int -> Handler HelloMessage
    helloHandler mAge =
      let
        sAge = case mAge of
                 Nothing -> "0"
                 Just ag -> show ag
      in
        return . HelloMessage $ sAge

app2 :: Application
app2 = serve appAPI2 myHandler

main :: IO ()
main = run 8080 app2

I can access /hello which returns { "msg" : 0} or /hello?age=20 which returns { "msg" : 20}. But if I set the age to be a non-integer parseable e.g. "foobar" which makes the url to be /hello?age=foobar and access it, it returns an error message about parsing error on "foobar".

This behave differently with Capture where if I give the same treatment it'll just return a http 400.

What is wrong my code?

Edit: After further exploration, it does return http 400 on parse error. Now I'm changing the question. How to return custom error message if that happens?

If you want to return custom error, you can pass `Text` instead of `Int`, parse it manually in your handler and throw your custom error. — Shersh, Jul 03 '18 at 04:19

Alp Mestanogullari · Accepted Answer · 2018-07-03T09:53:07.770

6

The default behaviour of QueryParam is to behave like this: error out if you can't decode, but return Nothing when not specified.

Since servant 0.13, you can however override this.

If you look at the definition of QueryParam, you can see that it is in fact just a special case of a more general QueryParam' type:

type QueryParam = QueryParam' '[Optional, Strict]

QueryParam' takes what we call "modifiers", which affect two things:

whether you can survive without a value for this parameter: if you can, your handler gets a Maybe a, if not you directly get an a but it errors out when no value is given. This is Required vs Optional.
whether you want decoding failures to be fatal or not: if you do, then when decoding fails servant errors out for you otherwise your handler gets an a. If you don't, then your handler gets an Either Text a and you're then free to do whatever you want in case of a decoding error (it's the Left case of the Either, with a textual error message). This is Strict vs Lenient.

So you probably want to define something like type MyQueryParam name a = QueryParam' '[Optional, Lenient] and use this whenever appropriate.

Does that solve your problem?

edited Jul 03 '18 at 09:53

answered Jul 03 '18 at 08:36

Alp Mestanogullari

1,042
7
13

Thank you, the Servant documentation doesn't seem to mention this anywhere, and I certainly couldn't find it in digging through the individual module docs. It hardly seems like a rare thing that you'd want to, for example, tell your users their error in a JSON response if they give an incorrect query parameter, rather than simply fail. – Robin Zigmond Nov 16 '19 at 02:47
If you sese a good place where this can be mentionned, we'd be happy to take the patch! :-) – Alp Mestanogullari Nov 19 '19 at 16:26
Unfortunately I'm very new to Servant, and pretty new to Haskell, I definitely don't feel I have the knowledge or experience to contribute, even if only to the documentation. But thank you for the offer nonetheless. (I'll mention in passing that there isn't any similar solution to the above for `QueryParams`, which returns a list. I got round it by using the [LenientData](https://hackage.haskell.org/package/http-api-data-0.4.1.1/docs/Web-HttpApiData.html#t:LenientData) type, but unfortunately this has not only added boilerplate to my handlers, it's made writing tests a lot more annoying.) – Robin Zigmond Nov 19 '19 at 21:06

Servant QueryParams parse error

1 Answers1