Delphi XE6: How to enumerate RCData resource names?

Question

I have embedded several resources into the executable, for instance language (text) files.

Below you can see the contents of Languages.rc file:

Language_English  RCDATA  Languages\English.ini
Language_German   RCDATA  Languages\German.ini
Language_Czech    RCDATA  Languages\Czech.ini

I found this answer, which definitely helps, however I have rather hard time implementing it.

Vlastimil Burián · Accepted Answer · 2018-04-22T08:44:43.080

Suppose you want to get the list of those resources as a EOL-delimited string, then the first step would be defining EnumRCDataProc function:

function EnumRCDataProc(hModule: HMODULE; lpszType, lpszName: PChar; lParam: NativeInt): BOOL; stdcall;
begin
  TStrings(lParam).Add(lpszName);
  Result := True;
end;

Once we have that done, we can get to work:

function EnumerateRCDataResourceNames: string;

var
  ExecutableHandle: HMODULE;
  ResourcesList: TStringList;

begin
  ExecutableHandle := LoadLibraryEx(PChar(Application.ExeName), 0, LOAD_LIBRARY_AS_DATAFILE);
  try
    ResourcesList := TStringList.Create;
    try
      EnumResourceNames(ExecutableHandle, RT_RCDATA, @EnumRCDataProc, NativeInt(ResourcesList));
      Result := ResourcesList.Text;
    finally
      ResourcesList.Free;
    end;
  finally
    FreeLibrary(ExecutableHandle);
  end;
end;

Remarks:

As is in the original answer (see question), it is not possible to use LOAD_LIBRARY_AS_DATAFILE_EXCLUSIVE or LOAD_LIBRARY_AS_IMAGE_RESOURCE as these types are no longer defined in Delphi XE6, at least AFAIK.
You can, however, define those constants, according to MSDN:
- LOAD_LIBRARY_AS_DATAFILE_EXCLUSIVE = $00000040
- LOAD_LIBRARY_AS_IMAGE_RESOURCE = $00000020

You can use those flags. If they aren't defined, then define them. The values are well known. — David Heffernan, Apr 22 '18 at 07:45
@DavidHeffernan Thank you for pointing it out. I hope I added the right values to my answer. Btw, is there any advantage for those constants over just using `LOAD_LIBRARY_AS_DATAFILE`? — Vlastimil Burián, Apr 22 '18 at 08:12
FWIW, the flags you mention are not defined in XE2 either. I doubt if they ever were, in (Winapi.)Windows.pas. — Rudy Velthuis, Apr 22 '18 at 11:36

Delphi XE6: How to enumerate RCData resource names?

1 Answers1