ANTLR4 repeating ANDs

Question

With the following rule:

expr:
 '(' expr ')'  #exprExpr
|   expr ( AND expr )+  #exprAnd
|  expr ( OR expr )+  #exprOr
|  atom #exprAtom
|  ID  #exprId
;

atom:
  '[' ID RELOP INT ']'
;

I would like to allow statements like this:

[a<3] and [b<4]
[a<3] or [b<4]
[a<3] or ([b<4]and [c<5])

but forbid statements like this:

[a<3] or [b<4] and [c<5]

This basic idea seems to work with this grammar. But there is one aspect/side effect, which I do not understand:

While parsing code with 3 atoms ( like atom1 and atom2 and atom3) the method exprAnd ist called twice (not once, as I would expect it to).

So code like this:

 public String visitExprAnd(myParser.ExprAndContext ctx)  {
String res = "";
int type=-1;

int nAtoms = ctx.atom().size();
for (int i=0;i<nAtoms;i++) { 
  String s = visit(ctx.expr(i));
}
return s;

}

does not work for all and-expressions at once.

So somehow I would have expected the exprAnd and exprOr rules to be more greedy.

How could one achieve this?

Answer 1

but forbid statements like this:

[a<3] or [b<4] and [c<5]

That is best done after parsing. Your grammar accepts this (and it should). You just need to walk the parse tree afterwards and reject it when you encounter it during a tree-traversal.

While parsing code with 3 atoms ( like atom1 and atom2 and atom3) the method exprAnd ist called twice (not once, as I would expect it to).

If you want to group these ANDs together, you should do something like this instead of grouping it all together in a single expr rule:

orExpr
 : andExpr ( OR andExpr )*
 ;

andExpr
 : atom ( AND atom )*
 ;

atom
 : '(' expr ')'         #atomExpr
 | '[' ID RELOP INT ']' #atomBracket
 | ID                   #atomId
 ;

EDIT

A complete example:

grammar Test;

parse
 : expr EOF
 ;

expr
 : orExpr
 ;

orExpr
 : andExpr ( OR andExpr )*
 ;

andExpr
 : atom ( AND atom )*
 ;

atom
 : '(' expr ')'            #atomExpr
 | '[' expr RELOP expr ']' #atomBracket
 | ID                      #atomId
 | INT                     #atomInt
 ;

RELOP : [<>] '='?;
AND   : 'and';
OR    : 'or';
INT   : [0-9]+;
ID    : [a-zA-Z_] [a-zA-Z_0-9]*;
SPACE : [ \t\r\n] -> skip;