How to set a variable by its symbolized name

Question

I'm learning crystal (just for fun) and trying to implement kind of []= method for a struct. Here is the first attempt:

struct Foo
  @str : String | Int32 # Have to share all the types, NOT OK
  @int : Int32 | String # Have to share all the types, NOT OK

  def initialize(@str = "foo", @int = 111)
  end

  def []=(variable, value)
    {% for ivar in @type.instance_vars %}
      @{{ivar}} = value if {{ivar.id.symbolize}} == variable
    {% end %}
  end
end

foo = Foo.new
foo[:str] = "bar" # OK
foo[:int] = 222   # OK

It works, but the disadvantage is all the instance variables should share the same type, otherwise the compiller will complain. My second attempt was to reimplement the method like this:

def []=(variable, value)
  {% for ivar in @type.instance_vars %}
    {% if ivar.id.symbolize == variable %} # ERROR: undefined macro variable 'variable'
      @{{ivar}} = value
    {% end %}
  {% end %}
end

But this doesn't work, as variable inside {%%} syntax can't be resolved. How to overcome this problem? Maybe there is other idiomatic approach to implement such method at all?

What's your use case? That seems highly dynamic and Crystal isn't supposed to be used like that. — asterite, Feb 08 '18 at 12:08
@asterite, I have a struct (kind of preset) with bunch of properties and try to update other class properties with that struct properties. — WPeN2Ic850EU, Feb 08 '18 at 12:24
Then why do you need symbols? You can just use a plain struct. — Johannes Müller, Feb 08 '18 at 12:26
@JohannesMüller, generally, the problem I'm trying to solve, could be expressed like: http://ix.io/Fu7/crystal — WPeN2Ic850EU, Feb 08 '18 at 13:08
@asterite, I don't know, how to. And I can't grep api docs by method name (copy) neither. Do you have any code snippet to demonstrate? — WPeN2Ic850EU, Feb 08 '18 at 16:57
Sure, just `@a = obj.a; @b = obj.b; @c = obj.c`. Something like that. — asterite, Feb 09 '18 at 17:42

score 1 · Accepted Answer · answered Feb 08 '18 at 11:58

You don't need the instance variables to have a union of all possible types, you can restrict to the matching type in the setter method:

struct Foo
  @str : String
  @int : Int32

  def initialize(@str = "foo", @int = 111)
  end

  def []=(variable, value)
    {% for ivar in @type.instance_vars %}
      if {{ivar.id.symbolize}} == variable
        if value.is_a?({{ ivar.type.id }})
          @{{ivar}} = value
        else
          raise "Invalid type #{value.class} for {{ivar.id.symbolize}} (expected {{ ivar.type.id }})"
        end
      end
    {% end %}
  end
end

foo = Foo.new
foo[:str] = "bar"
foo[:int] = 222
foo[:int] = "string"  # => Invalid type String for :int (expected Int32)

While that is certainly possible, it comes at the disadvantage that these type mismatches are only detected at runtime. You'll get better type safety if you access the properties directly (foo.int = "string" will not even compile). It should be possible to implement []= as a macro which could complain at compile time about type mismatches, but I'm not sure that's what you're looking for.

A better solution might be to just use a NamedTuple. Or maybe you don't need to access the fields using symbols at all. I don't know if there is a real use case for this.

Thank you! I think, there should be real usecases for this, e.g. Ruby has such method: http://ruby-doc.org/core-2.5.0/Struct.html#method-i-5B-5D-3D — WPeN2Ic850EU, Feb 08 '18 at 12:15
Yeah, but "because Ruby has it", doesn't mean there's a real use case for this in Crystal. Ruby is a dynamically typed language, Crystal statically typed. And there is a great benefit in having static type checking. — Johannes Müller, Feb 08 '18 at 12:25

How to set a variable by its symbolized name

1 Answers1