Automated labeling of logarithmic plots

Question

I would like to automate the graph axis values for a series of plots in Stata 13. In particular, I would like to show axis labels like 10^-1, 0, 10^1, 10^2 etc. by feeding the axis options macros.

The solution in the following blog post gives a good starting point:

• Labeling logarithmic axes in Stata graphs

I could also also produce nicer labels by using "10{sup:`x'}".

However, I cannot find the solution to the following additional elements:

1. the range of the axis labels would run from 10^-10 up to 10^10. Moreover, my baseline is ln, so log values are 2.3, 4.6, etc. In particular, the line below which only takes integers as input:

   label define expon `vallabel', replace
   

2. I would like to force the range of the axis values by graph (e.g. a particular axis runs from 10^-2 to 10^5). I understand that range() only extends axes, but does not allow to trim them.

Any ideas on either or both of the above?

This is a very straightforward output in R or Python, even standard without many additional arguments, but unfortunately not so in Stata.

Answer 1

Q1. You should check out niceloglabels from SSC as announced in this thread. niceloglabels together with other tricks and devices in this territory will be discussed in a column expected to appear in Stata Journal 18(1) in the first quarter of 2018.

Value labels are limited to association with integers but that does not bite here. All you need focus on is the text which is to be displayed as axis labels at designated points on either axis; such points can be specified using any numeric value within the axis range.

Your specific problem appears to be that one of your variables is a natural logarithm but you wish to label axes in terms of powers of 10. Conversion to a variable containing logarithms to base 10 is surely easy, but another program mylabels (SSC) can help here. This is a self-contained example.

* ssc inst mylabels  

sysuse auto, clear
set scheme s1color 

gen lnprice = ln(price) 
mylabels 4000 8000 16000, myscale(ln(@)) local(yla)

gen lnweight = ln(weight) 
mylabels 2 3 4, myscale(ln(1000*@))  suffix(" x 10{sup:3}")  local(xla)  

scatter lnprice lnweight, yla(`yla') xla(`xla') ms(Oh) ytitle(Price (USD)) xtitle(Weight (lb)) 

I have used different styles for the two axes just to show what is possible. On other grounds it is usually preferable to be consistent about style.

Broadly speaking, the use of niceloglabels is often simpler as it boils down to specifying xscale(log) or yscale(log) with the labels you want to see. niceloglabels also looks at a variable range or a specified minimum and maximum to suggest what labels might be used.

Q2. range() is an option with twoway function that allows extension of the x axis range. For most graph commands, the pertinent options are xscale() or yscale(), which again extend axis ranges if suitably specified. None of these options will omit data as a side-effect or reduce axis ranges as compared with what axis label options imply. If you want to omit data you need to use if or in or clone your variables and replace values you don't want to show with missing values in the clone.

FWIW, superscripts look much better to me than ^ for powers.

Answer 2

I have finally found a clunky but working solution. The trick is to first generate 2 locals: one to evaluate the axis value, another to denote the axis label. Then combine both into a new local. Somehow I need to do this separately for positive and negative values. I'm sure this can be improved...

// define macros
forvalues i  = 0(1)10 {
    local a`i' = `i'*2.3
    local b`i'  `" "10{sup:`i'}" "'
    local l`i' `a`i'' `"`b`i''"' 
}

forvalues i  = 1(1)10 {
    local am`i' = `i'*-2.3
    local bm`i'  `" "10{sup:-`i'}" "'
    local lm`i' `am`i'' `"`bm`i''"' 
}

// graph
hist lnx, ///
xl(`lm4' `lm3' `lm2' `lm1' `l0' `l1' `l2' `l3' `l4')