Clojure - Count occurences of nested key in nested map?

Question

I have a nested map like so:

{:A {:B {:A {:B {:A {:B 0}}}}}}

I want to count the occurrences of the pair [:A :B] so that in the case above, the result is 3.

My initial idea was to use clojure.walk/postwalk to traverse the map and increment a counter.

Is there a more optimal way of achieving this?

what if the input is `{:A {:B {:C {:A {:B {:A {:B 0}}}}}}}` ? the result should still be 3 ? if so, the accepted answer is wrong (it gives you `1`, obviously) — leetwinski, Jan 22 '18 at 20:13

score 4 · Accepted Answer · answered Jan 22 '18 at 20:31

tree-seq works out nice in this case:

(defn count-ab [data]
  (->> data
       (tree-seq coll? seq)
       (keep #(get-in % [:A :B]))
       count))

user> (def data {:A {:B {:A {:B {:A {:B 0}}}}}})
#'user/data

user> (count-ab data)
3

user> (def data-1 {:A {:B {:C {:A {:B {:A {:B 0}}}}}}})
#'user/data-1

user> (count-ab data-1)
3

user> (def data-2 {:A {:X {:A {:B 100}}
                       :B {:C {:A {:B {:A {:B 0}}}}}}})
#'user/data-2

user> (count-ab data-2)
4

score 1 · Answer 2 · answered Jan 22 '18 at 12:45

Because it's nested map, my pragmatic idea is to traverse recursively and count:

(defn do-count [m]
   (loop [m m
          counter 0]
       (if-let [m* (get-in m [:A :B])]
           (recur m* (inc counter))
           counter)))


(do-count {:A {:B {:A {:B {:A {:B 0}}}}}}) ;==> 3

Ben Hammond · Answer 3 · 2018-01-22T16:07:47.130

I would suggest writing a function to turn the deeply nested map into a flat map keyed by paths

 (defn flatten-map
  "unwind deeply nested map into map of paths and vals"
  ([m] (into {} (flatten-map [] m)))
  ([path m]
   (if (map? m)
     (mapcat (fn [[k v]]
               (flatten-map (conj path k) v))
             m)
     [[path m]])))

you can use this to count the adjacent [:a :b] keys like this

(->> {:A {:B {:A {:B {:A {:B 0}}}}}}
     flatten-map
     keys 
     (mapcat #(partition 2 1 %))
     (filter #(= [:A :B] %))
     count)

Clojure - Count occurences of nested key in nested map?

3 Answers3