How do you create an archive file in Terraform?

Question

I have this code in terraform:

data "archive_file" "lambdazip" {

  type        = "zip"
  output_path = "lambda_launcher.zip"

  source_dir = "lambda/etc"
  source_dir = "lambda/node_modules"

  source {
    content  = "${data.template_file.config_json.rendered}"
    filename = "config.json"
  }
}

I get the following errors when I do terraform plan:

* data.archive_file.lambdazip: "source": conflicts with source_dir 
("lambda/node_modules")
* data.archive_file.lambdazip: "source_content_filename": conflicts 
with source_dir ("lambda/node_modules")
* data.archive_file.lambdazip: "source_dir": conflicts with 
source_content_filename ("/home/user1/experiments/grascenote-
poc/init.tpl")

I am using terraform version v0.9.11

Answer 1

@Ram is correct. You cannot use both source_dir and source arguments in the same archive_file data source.

config_json.tpl

{"test": "${override}"}

Terraform

Terraform 0.12 and higher

Use templatefile()

main.tf

# create the template file config_json separately from the archive_file block
resource "local_file" "config" {
  content = templatefile("${path.module}/config_json.tpl", {
    override = "my value"
  })
  filename = "${path.module}/lambda/etc/config.json"
}

Terraform 0.11 and below

Use template provider.

main.tf

data "template_file" "config_json" {
  template = "${file("${path.module}/config_json.tpl")}"
  vars = {
    override = "my value"
  }
}

# create the template file config_json separately from the archive_file block
resource "local_file" "config" {
  content  = "${data.template_file.config_json.rendered}"
  filename = "${path.module}/lambda/etc/config.json"
}

Next steps

Add to main.tf

# now you can grab the entire lambda source directory or specific subdirectories
data "archive_file" "lambdazip" {
  type        = "zip"
  output_path = "lambda_launcher.zip"

  source_dir = "${path.module}/lambda/"

  depends_on = [
    local_file.config,
  ]
}

Terraform run

$ terraform init
$ terraform apply
data.template_file.config_json: Refreshing state...
data.archive_file.lambdazip: Refreshing state...

An execution plan has been generated and is shown below.
Resource actions are indicated with the following symbols:
  + create

Terraform will perform the following actions:

  + local_file.config
      id:       <computed>
      content:  "{\"test\": \"my value\"}\n"
      filename: "/Users/user/lambda/config.json"


Plan: 1 to add, 0 to change, 0 to destroy.

Do you want to perform these actions?
  Terraform will perform the actions described above.
  Only 'yes' will be accepted to approve.

  Enter a value: yes

local_file.config: Creating...
  content:  "" => "{\"test\": \"my value\"}\n"
  filename: "" => "/Users/user/lambda/config.json"
local_file.config: Creation complete after 0s (ID: 05894e86414856969d915db57e21008563dfcc38)

Apply complete! Resources: 1 added, 0 changed, 0 destroyed.

List the contents of the new zip file

$ unzip -l lambda_launcher.zip
Archive:  lambda_launcher.zip
  Length      Date    Time    Name
---------  ---------- -----   ----
       21  01-01-2049 00:00   etc/config.json
       22  01-01-2049 00:00   node_modules/index.js
---------                     -------
       43                     2 files

Answer 2

In case of node.js lambda function,

You need to use "resource.local_file" with "depends_on". And separate "rendering file" with "directory".

First, Put static directory(etc, node_modules) into "lambda" folder without rendering files.

Second, Put rendering files into any other path.

data "template_file" "config_json" {
  template = "${file("${path.module}/config_json.tpl")}"
  vars = {
    foo = "bar"
  }
}

resource "local_file" "config_json" {
  content  = "${data.template_file.config_json.rendered}"
  filename = "${path.module}/lambda/config.json"
}

data "archive_file" "lambda_zip" {
  type        = "zip"
  output_path = "${path.module}/lambda_function.zip"
  source_dir = "${path.module}/lambda"

  # It is important to this process.
  depends_on = [
    "local_file.config_json" 
  ]
}

resource "aws_lambda_function" "lambda" {
  filename         = "${path.module}/lambda_function.zip"
  function_name    = "lambda_function"
  role             = "${aws_iam_role.lambda.arn}"
  handler          = "index.handler"
  runtime          = "nodejs10.x"
}

resource "aws_iam_role" "lambda" {
...