Insert lines at specific location in file using perl script

Question

Want to add a new line in a file using perl script. I have tried but no luck

 if($correctedContents[$i] ~= /second line/){
 @data = $correctedContents[$i]
  push (@data, '\n TEST Line');

For example: add a "TEST Line" into a file whenever it find 'second line' line.

file1.txt,

first line
second line
third line

first line 
second line 
third line

.....

After added a new line expected output:

first line
second line
TEST Line
third line

first line 
second line 
TEST Line
third line

Thanks in Advance

Answer 1

You haven't really shown us enough of your code for us to be very much help. But, in particular, you haven't shown any code where you write the changed data back to an output file.

In general, tasks like this boil down to three stages:

1. Read data from file.
2. Update data in some way.
3. Write changed data back to file.

One common approach is to have two filehandles open - one to your input file and another to a new output file. That makes it simple to process the file a line at a time.

while (<$input_fh>) {
  if (this is a line you need to change) {
    # make changes to line (which is in $_)
    # Perhaps print an extra line here.
  }
  print $output_fh $_;
}

Another approach (which trades speed for ease of use) is to use the Tie::File module (which is part of all Perl distributions since 5.8).

As always, the Perl FAQ is a good place for more information. In this case, you probably want to look at perlfaq5, which contains the question How do I change, delete, or insert a line in a file, or append to the beginning of a file?

Update: You already have one (slightly problematic) Tie::File-based solution. So here's mine:

#!/usr/bin/perl

use strict;
use warnings;

use Tie::File;

tie my @lines, 'Tie::File', 'somefile.txt'
  or die "Can't tie file: $!\n";

for (@lines) {
  $_ .= "\nTEST line" if $_ eq 'second line';
}

Answer 2

You may use Tie::File can get the output what you have expect

use Tie::File;

my $inputFile = "test.txt";

my @array;
tie @array, 'Tie::File', $inputFile or die "Error: Couldn't tie the \"$inputFile\" file: $!";
my $len = join "\n", @array;

if($len=~m/second line/i) {  $len=~s/second line/$&\nTEST Line/ig;  }

@array = split/\n/, $len;
untie @array;

Tie::File will replace the string in a same input file.