Haskell instance read for newtype that is just an int

Question

I am new to Haskell and I want to be able to a newtype so I can tell what is what, but I also have to read it from a string. I have

newtype SpecialId Int
    deriving (Eq, Ord, Show)

I want to be able to read "5" :: SpecialId if I derive Read in the newtype it doesn't work it only works on read "SpecialId 5" :: SpecialId. I have tried

instance Read SpecialId where
    readsPrec _ s = read s

But this gives me

SpecialId *** Exception: Prelude.read: no parse

You are Asking Haskell that `read`, reads an `[(SpecialId,String)]`, and this fails, since it does not begin with a `'['` char. — Willem Van Onsem, Nov 02 '17 at 13:22
Your syntax for defining the new type is wrong; it should be `newtype SpecialId = SpecialId Int deriving (Eq, Ord, Show)`. — chepner, Nov 02 '17 at 13:35

score 9 · Accepted Answer · answered Nov 02 '17 at 13:28

This is possible since GHC 8.2 using -XDerivingStrategies:

{-# LANGUAGE GeneralizedNewtypeDeriving #-}
{-# LANGUAGE DerivingStrategies         #-}

newtype SpecialId = SpecialId Int
    deriving stock   (Eq, Ord, Show)
    deriving newtype Read

In ghci:

ghci> read "5" :: SpecialId 
SpecialId 5

score 6 · Answer 2 · answered Nov 02 '17 at 13:38

You don't need a language extension if you're willing to forward to the Int instance manually:

instance Read SpecialId where
    readsPrec n s = [ (SpecialId x, y) | (x, y) <- readsPrec n s ]

Despite appearances this is not a recursive use of readsPrec: We call the Int version of readsPrec to get a list of (Int, String) pairs, then we use a list comprehension to wrap every Int in a SpecialId.

Haskell instance read for newtype that is just an int

2 Answers2