Prolog - Multiplication of matrix with its transpose

Question

I need to find the product of the matrix A with its transpose A^t, so I should get a third matrix B=A*A^t. Example: A=[[1,2],[3,4]] (then A^t=[[1,3],[2,4]]) so B=[[5,11],[11,25]] (each sub list is a row of the matrix)

Firstly I think that this should be easier as the columns of A^t are the rows of A. So for the dot product of the row of A with the column of A^t I think I can use this:

sum([M|Ms],[N|Ns],Sum) :-
    sum(Ms,Ns,S),
    Sum is S+M*N.
 sum([],[],0).

I also can't use clpfd or if-else.

I've been stuck and don't know what to do next.

Well you already found out how to calculate a single element. So now you have to write a predicate that calculates your `sum` n^2 times. — Willem Van Onsem, Nov 01 '17 at 07:13
Related to https://stackoverflow.com/questions/55687499/matrix-multiplication-prolog — , Jun 05 '21 at 11:17

score 0 · Answer 1 · answered Nov 01 '17 at 09:44

It is correct that you can use the dot-product of the rows of matrix A for this. Although you probably better name this function dot_product/3 instead of sum/3.

The only task that is left, is to calculate this dot product for every two rows in A. So the i,j-th element of B is the dot product of A_i and A_j.

We can construct a predicate that calculates a row of B with:

transprod_row(A, AI, Row) :-
    maplist(dot_product(AI), A, Row).

Furthermore we can then calculate the transprod/3 with another maplist/3:

transprod(A, B) :-
    maplist(transprod_row(A),A,B).

or in full:

dot_product([],[],0).
dot_product([M|Ms],[N|Ns],Sum) :-
    dot_product(Ms,Ns,S),
    Sum is S+M*N.

transprod_row(A, AI, Row) :-
    maplist(dot_product(AI), A, Row).

transprod(A, B) :-
    maplist(transprod_row(A),A,B).

This then generates:

?- transprod([[1,2],[3,4]],B).
B = [[5, 11], [11, 25]].

The code is not yet the most elegant, nor is it very efficient, since B_ij is equal to B_ji so we can save half of the work. Furthermore if elements in the matrix are missing, then we can not calculate the product. I leave this as an exercise.

Prolog - Multiplication of matrix with its transpose

1 Answers1