Two newlines in one echo command

Question

Simply put, I've set a most basic text progress indicator in a Windows XP/Windows 7 batch file that writes just after a command line tool's output while it works, because it doesn't look like it does anything for a bit. I do so by piping the blurb after the command as such:

app.exe -args "file"|echo Writing "file"...

This results in something like the following:

_______________
|app for work |  
|ver:2 10/2009|  
|_____________|  
Writing "file"...

Is there a way to slip a newline in between the application's output and my output?

Things I've done and failed:

|echo.|echo
|echo.|echo.|echo
|echo.&echo.&echo
|echo [alt+255/hex:FF/ÿ/EOL][same again]
|echo -e \r\r (lol)
|echo.. (nope!)

The &'s are probably delayed until after the application does its thing, and by then it's too late... Have I missed something? Is it even possible? I know this is not truly important, but I'm very curious.

Why the heck are you even piping `app`'s output into `echo`? `echo` doesn't take input so that whole construct is rather maeningless. — Joey, Jan 23 '11 at 13:19

score 1 · Accepted Answer · answered Jan 15 '11 at 17:19

1

From your example, I suspect that app.exe actually sends its output to standard error, rather than standard output. Otherwise its output would have been sent to the pipe and echo would have gobbled it up.

How about this:

app.exe -args "file" | (echo. & echo Writing "file")

answered Jan 15 '11 at 17:19

thkala

84,049
23
157
201

Yup, that's it! Works perfectly. I don't yet understand the difference between commands in and out of parentheses, but obviously it's important. Thank you muchly for your effort. – Zandro Jan 15 '11 at 17:27
...it dawned on me. In-parentheses commands are read through to the end, inclusive of separating ampersands within. I knew it all along! – Zandro Jan 15 '11 at 17:40

score 1 · Answer 2 · answered Jan 15 '11 at 22:37

Ok, in your case, there are multiple problems.

Normally you can echo a line feed with a small trick

setlocal EnableDelayedExpansion
set LF=^


rem Two empty lines are neccessary for the LF creation
rem In the variable <lf> is one line feed character
echo Line1!lf!Line2
------ OUTPUT -----
Line1
Line2

But in your case this doesn't work, because the pipe breaks the delayed expansion.

But the pipe will make more problems, as it starts two asynchronous tasks.

In reallity your app.exe runs as task1 and echo Writing file runs as task2. So it can happen that task2 will be executed before task1, the output would be

app.exe -args "file" | (echo. & echo Writing "file")

Writing "file"...
_______________
|app for work |
|ver:2 10/2009|
|_____________|

instead of

_______________
|app for work |
|ver:2 10/2009|
|_____________|

Writing "file"...

You can test it (on the cmdline)

echo one >&2 | echo two

In the most cases the output is:

one
two

But not always!

I've been wanting to say thank you for this. Sadly, I haven't had enough reputation. Please accept my ethereal vote instead! — Zandro, Feb 21 '11 at 01:55

score 0 · Answer 3 · answered Jan 15 '11 at 16:53

0

you might want to group your two echo commands:

app.exe -args "file" & ( echo ""; echo Writing "file" )

answered Jan 15 '11 at 16:53

bjelli

9,752
4
35
50

I think the OP is using Windows' cmd.exe – thkala Jan 15 '11 at 16:55
Thanks for the help, but is this bash language? In Windows batch it waits until the app terminates then prints: ""; echo Writing "file" – Zandro Jan 15 '11 at 17:00

score 0 · Answer 4 · answered Jan 15 '11 at 16:59

0

What about

echo -e "`app.exe -args \"file\"` \n Writing file"

answered Jan 15 '11 at 16:59

ktm5124

11,861
21
74
119

This is all nice and Unix-y, but the OP is using Windows – thkala Jan 15 '11 at 17:02
Yeah, haha. Maybe the ` syntax transfers? – ktm5124 Jan 15 '11 at 17:03
Sorry, afaik Windows' echo is barebones. I tried -e as a sanity test. – Zandro Jan 15 '11 at 17:05
The DOS shell is completely different from `sh`. They're both shells and that's about it. It has nowhere near the same capabilities and when it does the syntax is usually completely different. – thkala Jan 15 '11 at 17:06

Two newlines in one echo command

4 Answers4