5

In mathematica (I am using mma 5.0 ( guess pretty old)), if I type the following as one line:

Needs["Graphics`Master`"]; Animate[Plot[Sin[n x], {x, 0, 2 Pi}, Axes -> False], {n, 1, 6, 1}]

I then got a lot of errors/warnings. But if I type them in separately, it is working fine. How to make it work in one code block?

Thanks!

Qiang Li
  • 10,593
  • 21
  • 77
  • 148

2 Answers2

12

As belisarius points out, your question as it stands is a bit v5-centric. The problem, however, still exists in current versions. As an example

Needs["Combinatorica`"]
ToCycles[{3, 4, 1, 2}]

works fine, while (after restarting the kernel), 

Needs["Combinatorica`"]; ToCycles[{3, 4, 1, 2}]

fails with an error that

"ToCycles::shdw: Symbol ToCycles appears in multiple contexts {Combinatorica`,Global`}; definitions in context Combinatorica` may shadow or be shadowed by other definitions."

In Mathematica terms, the reason the one-liner doesn't work is that Mathematica tries to resolve all symbols in the line before evaluating Needs (this was a surprise to me). This resolves ToCycles to Global`ToCycles (thus entering this symbol in the symbol table), before Needs gets a chance to load the definition of Combinatorica`ToCycles and add Combinatorica to the $ContextPath. To make the one-liner work, you must use the full name of ToCyles:

Needs["Combinatorica`"]; Combinatorica`ToCycles[{3, 4, 1, 2}]

To understand the error, you need to know that all Symbols in Mathematica have a full name of the form context`name. A context is similar to a namespace in many other languages. Now, if a symbol (such as ToCycles) is referenced without a context, Mathematica will look through the contexts currently in $ContextPath and see if the symbol is defined in any of those contexts. If not, the symbol is resolved in the current context, $Context which is Global in normal use.
When you load a package, the symbols of that package are defined in a package context (e.g. Combinatorica), and when the package is fully loaded this context is added to the $ContextPath so that you can access the symbols by their short name.
Now, you can see what the error means: Since the Combinatorica has not yet been loaded when the symbols are resolved, ToCycles resolves to Global`ToCycles. After the package loads, Mathematica helpfully checks that all short names are unique, and finds in this case that the short name ToCycles is now defined in two contexts on $ContextPath one thus "shadowing" the other. To refer to a specific of these symbols, you must use the full name, e.g. Combinatorica`ToCycles.

To resolve a shadow conflict, simply Remove the unwanted symbol:

Remove[Global`ToCycles]

Don't know how readable this was, but hope it helps a bit...

Janus
  • 5,421
  • 2
  • 26
  • 37
  • @Janus: how to use Combinatorica'ToCycles? Also, how to resolve the issue of writing Needs and the ToCycles in the same code block? Many thanks! – Qiang Li Jan 12 '11 at 02:19
  • 1
    Well explained! It is a bit surprising that the naive 1-liner doesn't work. – Simon Jan 12 '11 at 02:19
  • 1
    @Quang Li: It has to be a "backtick" between Combinatorica and ToCycles, but it took me a while to figure out how to enter a literal backtick in my answer. Should be ok now? Also, I added the correct one-liner before I even saw your comment :) – Janus Jan 12 '11 at 02:26
  • 1
    @Simon: Thanks! It surprised me as well. Always thought that semicolons and line breaks were completely interchangeable... – Janus Jan 12 '11 at 02:28
  • 1
    +10 Never happened to me ... just because I always use Needs[] in a line on its own ... Good to know why! – Dr. belisarius Jan 12 '11 at 03:21
  • Turns out that `;` is actually a shorthand for `CompoundExpression` which I guess is why things are different. Still, symbol resolution isn't really included in http://reference.wolfram.com/mathematica/tutorial/Evaluation.html :) – Janus Jan 12 '11 at 04:44
  • @Janus: pay attention that semicolons and line breaks are not interchangeable in another way: `1; (% + 1)` will return `2`, while `1; (% + 1)` will return something that depends on your previous results. – tsvikas Jan 12 '11 at 16:50
2

You are supposed to put the Needs[] call(s) at the top of a notebook in a separate block, or on the first isolated line of a package.m file.

The kernel reads the whole line and parses it, including deciding on the contexts for symbols, before beginning to evaluate it. To avoid problems, do not use semicolons. Put two newlines after every statement in a package. Especially after the BeginPackage[] and/or Needs[].

Edward Huff
  • 21
  • 3