Spock: Return input parameter in Stubs

Question

Given an method with a parameter in Java, e.g.

public class Foo {
   public Bar theBar(Bar bar) { /*... */ }   
}

When stubbing/ mocking foo, how do I tell it to accept any argument and return it? (Groovy)

def fooStub = Stub(Foo) {
  theBar(/*what to pass here*/) >> { x -> x }
}

As you can see I passed the identity function. However I do not know what to pass as argument. _ does not work because it is an ArrayList and thus not of type Bar

Do you have `@CompileStatic` or `@TypeChecked` on your spec? could you post your whole code, there is no reason why `_` shouldn't work. — Leonard Brünings, Oct 07 '17 at 21:15
Just ran into the same setup and situation. Trying to stub a Java class from Spock + Groovy and I only want to return the method's input, no more no less. Since I have no idea what's going on I simply leave my solution as a comment and I'd appreciate if someone could enlighten me. It seems the `x` input before the arrow is actually the entire arguments list of the method call? Doing the following solves the problem: `theBar(_) >> { args -> args.get(0) }`. But why is that necessary? How to express this correctly without any hacks? — tiguchi, Apr 24 '19 at 23:08

score 10 · Answer 1 · answered Oct 06 '17 at 14:32

You can stub Foo class in following way:

Foo foo = Stub(Foo)
foo.theBar(_ as Bar) >> { Bar bar -> bar }

And here is full example:

import groovy.transform.Immutable
import spock.lang.Specification

class StubbingSpec extends Specification {

    def "stub that returns passed parameter"() {
        given:
        Foo foo = Stub(Foo)
        foo.theBar(_ as Bar) >> { Bar bar -> bar }

        when:
        def result = foo.theBar(new Bar(10))

        then:
        result.id == 10
    }

    static class Foo {
        Bar theBar(Bar bar) {
            return null
        }
    }

    @Immutable
    static class Bar {
        Integer id
    }
}

Did you try the same with `Foo` and `Bar` being Java classes? — user3001, Oct 07 '17 at 12:21
@user3001 Yes, it works exactly the same when `Foo` and `Bar` are Java classes, just tested this example and got same result. — Szymon Stepniak, Oct 07 '17 at 15:10

score 0 · Answer 2 · answered Oct 06 '17 at 14:25

0

I'm not sure what you mean. _ is the right thing to pass. Why do you think it is an ArrayList? It is of type Object and can be used for anything.

answered Oct 06 '17 at 14:25

Vampire

35,631
4
76
102

That means that in Java, it has the wrong type (not `Bar`), right? – user3001 Oct 07 '17 at 12:16
So? Spock is Groovy based, you cannot use Spock with Java. – Vampire Oct 07 '17 at 20:25

Spock: Return input parameter in Stubs

2 Answers2