Export Fields that are Visible Equals to True in DataGridView

Question

I found this post about DataGridView to CSV File and I am wondering if someone knows how to export fields that are only Visible = True?

Private Sub ExportCSVButton_Click(sender As Object, e As EventArgs) Handles ExportCSVButton.Click
        Dim headers = (From header As DataGridViewColumn In PadGridView.Columns.Cast(Of DataGridViewColumn)()
                       Select header.HeaderText).ToArray
        Dim rows = From row As DataGridViewRow In PadGridView.Rows.Cast(Of DataGridViewRow)()
                   Where Not row.IsNewRow
                   Select Array.ConvertAll(row.Cells.Cast(Of DataGridViewCell).ToArray, Function(c) If(c.Value IsNot Nothing, c.Value.ToString, ""))
        Using sw As New IO.StreamWriter("export.csv")
            sw.WriteLine(String.Join(",", headers))
            For Each r In rows
                sw.WriteLine(String.Join(",", r))
            Next
        End Using
        Process.Start("export.csv")
End Sub

If you have columns which are not visible, just add a test for that to the 2 queries. Please read [ask] and take the [tour] — Ňɏssa Pøngjǣrdenlarp, Aug 14 '17 at 14:12

score 1 · Answer 1 · answered Aug 14 '17 at 16:35

Get the visible columns in an array, then you can use that to filter the headers and the row cells:

   Dim visibleColumns = (From header As DataGridViewColumn In PadGridView.Columns.Cast(Of DataGridViewColumn)()
                   Where header.Visible
                  Select header.Index).ToArray

    Dim headers = (From header As DataGridViewColumn In PadGridView.Columns.Cast(Of DataGridViewColumn)()
                   Where visibleColumns.Contains(header.Index)
                  Select header.HeaderText).ToArray

    Dim rows = From row As DataGridViewRow In PadGridView.Rows.Cast(Of DataGridViewRow)()
               Where Not row.IsNewRow
           Select Array.ConvertAll((From x In row.Cells.Cast(Of DataGridViewCell).ToArray Where visibleColumns.Contains(x.ColumnIndex)).ToArray, Function(c) If(c.Value IsNot Nothing, c.Value.ToString, ""))

    Using sw As New IO.StreamWriter("export.csv")
        sw.WriteLine(String.Join(",", headers))
        For Each r In rows
            sw.WriteLine(String.Join(",", r))
        Next
    End Using

    Process.Start("export.csv")

Export Fields that are Visible Equals to True in DataGridView

1 Answers1