Clojure, Compojure: Reading Post Request RAW Json

Question

I am able to read RAW JSON of Post Request. But Not sure that I am doing it in right way or not?

CODE

(ns clojure-dauble-business-api.core
  (:require [compojure.api.sweet :refer :all]
            [ring.util.http-response :refer :all]
            [clojure-dauble-business-api.logic :as logic]
            [clojure.tools.logging :as log]
            [clojure-dauble-business-api.domain.artwork])
  (:import [clojure_dauble_business_api.domain.artwork Artwork]))

(defapi app
  (GET "/hello" []
    (log/info "Function begins from here")
    (ok {:artwork (logic/artwork-id 10)}))
  (POST "/create" params
   (log/info "Create - Function begins from here and body" (:name (:artwork (:params params))))
   (ok {:artwork (logic/create-city (:name (:artwork (:params params))))})))

RAW JSON Of POST Request

{
  "artwork": {
    "id": 10,
    "name": "DEFAULT"
  }
}

using this line (:name (:artwork (:params params))) to fetch "name" value from the above RAW Json.

If I am not doing in right way, Please guide me what will be the right way?

score 4 · Accepted Answer · answered Jul 25 '17 at 13:35

If I understand your question correctly, it looks like you are asking if there's a more "proper" way to fetch :name with less awkward nesting of parentheses?

To retrieve a value such as :name from a nested associative structure (hash-map) you can use get-in:

(get-in params [:params :artwork :name])

This is neater and easier to read (left to right) with less nesting, but it is also a safer way to attempt to fetch a value, because get-in will return nil if it can't find a key in the sequence of keys.

score 1 · Answer 2 · answered Jul 25 '17 at 20:43

You seem to be using compojure-api, which has helpers for input & output coercion. You can use both :body or :body-params key to define the models and validation, see docs for details.

Here's a sample dummy api with Leiningen:

lein new compojure-api artwork
cd artwork

set the contents of src/artwork/handler.clj into:

(ns artwork.handler
  (:require [compojure.api.sweet :refer :all]
            [ring.util.http-response :refer :all]
            [schema.core :as s]))

;; define a Schema for validation
(s/defschema Artwork
  {:id Long
   :name String})

;; dummy ring-api with swagger-docs
(def app
  (api
    {:swagger
     {:ui "/"
      :spec "/swagger.json"
      :data {:info {:title "Artwork"
                    :description "Lovely artwork api"}
             :tags [{:name "api", :description "some apis"}]}}}

    (context "/api" []
      :tags ["api"]

      ;; endpoint with Schema coercion
      (POST "/create" []
        :return Artwork
        :body [body Artwork]
        :summary "creates artwork"
        (ok body)))))

and run lein ring server from the command line. You should see a swagger-ui with one endpoint, consuming Artwork in client-defined format (JSON, EDN or Transit).

Hope this helps.

Clojure, Compojure: Reading Post Request RAW Json

2 Answers2