Create a Boolean column displaying comparison between 2 other columns in kdb+

Question

I'm currently learning kdb+/q. I have a table of data. I want to take 2 columns of data (just numbers), compare them and create a new Boolean column that will display whether the value in column 1 is greater than or equal to the value in column 2.

I am comfortable using the update command to create a new column, but I don't know how to ensure that it is Boolean, how to compare the values and a method to display the "greater-than-or-equal-to-ness" - is it possible to do a simple Y/N output for that?

Thanks.

score 6 · Accepted Answer · answered Jun 14 '17 at 15:10

6

/ dummy data
q) show t:([] a:1 2 3; b: 0 2 4)
    a b
    ---
    1 0
    2 2
    3 4

/ add column name 'ge' with value from b>=a
q) update ge:b>=a from t
    a b ge
    ------
    1 0 0
    2 2 1
    3 4 1

answered Jun 14 '17 at 15:10

MdSalih

1,978
10
16

1

Thank you! Another simple method. Great help. – Jonathan Jun 14 '17 at 15:23
This would be marginally faster than the accepted answer – Manish Patel Jun 15 '17 at 07:48

score 1 · Answer 2 · answered Jun 14 '17 at 15:13

1

Use a vector conditional: http://code.kx.com/q/ref/lists/#vector-conditional

    q)t:([]c1:1 10 7 5 9;c2:8 5 3 4 9)
    q)r:update goe:?[c1>=c2;1b;0b] from t
    c1 c2 goe
    -------------
    1  8  0
    10 5  1
    7  3  1
    5  4  1
    9  9  1

Use meta to confirm the goe column is of boolean type:

  q)meta r
   c      | t f a
   -------| -----
   c1     | j
   c2     | j
   goe    | b

answered Jun 14 '17 at 15:13

jomahony

1,662
6
9

Fantastic, and thank you. As usual with these sorts of things, it is far simpler than I imagined. – Jonathan Jun 14 '17 at 15:23
1

For what it's worth, you don't need the vector conditional. Using the greater than operator will generate a list of booleans for you `update goe:c1>=c2 from t` – Conor Cadogan Jun 14 '17 at 21:48

score 0 · Answer 3 · answered Jun 03 '18 at 00:20

The operation <= works well with vectors, but in some cases when a function needs atoms as input for performing an operation, you might want to use ' (each-both operator).

e.g. To compare the length of symbol string with another column value

q)f:{x<=count string y}
q)f[3;`ab]
0b

q)t:([] l:1 2 3; s: `a`bc`de)
q)update r:f'[l;s] from t
l s  r
------
1 a  1
2 bc 1
3 de 0

Create a Boolean column displaying comparison between 2 other columns in kdb+

3 Answers3