Automatically choose an assumption from local context

Question

I have a proof script with a section that looks like this:

  - destruct (IHx1 _ _ H3). subst. destruct (IHx2 _ _ H7). congruence.
  - destruct (IHx1 _ _ H6). congruence.
  - destruct (IHx1 _ _ H3). subst. destruct (IHx2 _ _ H7). congruence.
  - destruct (IHx1 _ _ H6). congruence.
  - destruct (IHx  _ _ H2). congruence.
  - destruct (IHx  _ _ H5). congruence.
  - destruct (IHx  _ _ H2). congruence.
  - destruct (IHx  _ _ H8). congruence.
  - destruct (IHx  _ _ H8). congruence.
  - destruct (IHx  _ _ H8). congruence.
  - destruct (IHx  _ _ H8). congruence.
  - destruct (IHx  _ _ H7). congruence.
  - destruct (IHx  _ _ H4). congruence.
  - destruct (IHx1 _ _ H8). congruence.
  - destruct (IHx1 _ _ H5). subst. destruct (IHx2 _ _ H9).

It seems like it would be a choice candidate for using ; to solve cleanly, unfortunately the hypotheses are all over the place. How can I collapse the various sub-proofs together?

Please avoid putting full solutions to exercises in SF on the internet! — Zimm i48, May 28 '17 at 10:01
Didn't you see the only thing in red in the [introduction](https://www.cis.upenn.edu/~bcpierce/sf/current/Preface.html#lab12)? — Zimm i48, May 28 '17 at 10:03
I apologize! I'll edit out my solution as soon as it has an answer. I would remove it now but I don't have another equally good demonstration of the problem I'm trying to demonstrate. — Carl Patenaude Poulin, May 28 '17 at 17:57
I think you should at least edit the names to make it hard to google this solution. — Anton Trunov, May 29 '17 at 07:41
I've removed the information that identified the question. Sorry for having lacked discretion :o — Carl Patenaude Poulin, May 30 '17 at 22:13

Anton Trunov · Accepted Answer · 2017-05-29T12:48:17.537

The cases where we have only one induction hypothesis can be solved using the following piece of Ltac (see the manual, chapter 9):

match goal with
  IH : forall st2 s2, ?c / ?st \\ s2 / st2 -> _,
  H : ?c / ?st \\ _ / _
  |- _ => now destruct (IH  _ _ H)
end

Where variables prefixed with question marks, e.g. ?c, ?st, etc. are pattern-matching metavariables, commas separate hypotheses and the turnstile symbol (|-) separates the hypotheses from the goal. Here we are looking for an induction hypothesis IH and a compatible hypothesis H so we could apply IH to H. The ?c / ?st part ensures IH and H are compatible.

The subgoals with two induction hypotheses can be solved analogously:

match goal with
  IH1 : forall st2 s2, ?c1 / ?st \\ s2 / st2 -> _,
  IH2 : forall st2 s2, ?c2 / _ \\ s2 / st2 -> _,
  H1 : ?c1 / ?st \\ _ / ?st'',
  H2 : ?c2 / ?st'' \\ _ / st2
  |- _ => now destruct (IH1  _ _ H1); subst; destruct (IH2 _ _ H2)
end

Of course, if you want you can bind names to those custom tactics, use tactical with them and so on:

Ltac solve1 :=
  try match goal with
        IH : forall st2 s2, ?c / ?st || s2 / st2 -> _,
        H : ?c / ?st || _ / _
        |- _ => now destruct (IH  _ _ H)
      end.

Automatically choose an assumption from local context

1 Answers1