Retrieve a whole node as a string with XmlSlurper

Question

I want to retrieve the elements of <logs> as array of String and I am trying the following:

import groovy.util.XmlSlurper

def payload = '''<logs>
<log>
  <text>LOG 1</text>
  <timestamp>2017-05-18T16:20:00.000</timestamp>
</log>
<log>
  <text>LOG 2</text>
  <timestamp>2017-05-18T16:20:00.000</timestamp>
</log>
</logs>'''

def logs = new XmlSlurper().parseText(payload)
def result = []
logs.log.each{
  result.add(it)
}
result

However, I am getting the values, but I would like to get the whole node as text, more or less this:

[<log>
  <text>LOG 1</text>
  <timestamp>2017-05-18T16:20:00.000</timestamp>
</log>,
<log>
  <text>LOG 2</text>
  <timestamp>2017-05-18T16:20:00.000</timestamp>
</log>]

Is this at all possible with XmlSlurper or should I use some String operations?

score 4 · Accepted Answer · answered May 19 '17 at 07:51

You can use XmlUtil but have to remove the xml declaration:

import groovy.util.XmlSlurper
import groovy.xml.XmlUtil

def payload = '''<logs>
<log>
  <text>LOG 1</text>
  <timestamp>2017-05-18T16:20:00.000</timestamp>
</log>
<log>
  <text>LOG 2</text>
  <timestamp>2017-05-18T16:20:00.000</timestamp>
</log>
</logs>'''

def logs = new XmlSlurper().parseText(payload)

def result = logs.log.collect { 
  XmlUtil.serialize(it).replaceAll(/<.xml.*?>/,"") 
}

println result

score 1 · Answer 2 · answered May 18 '17 at 16:05

Try this:

    def payload = '''<logs>
<log>
  <text>LOG 1</text>
  <timestamp>2017-05-18T16:20:00.000</timestamp>
</log>
<log>
  <text>LOG 2</text>
  <timestamp>2017-05-18T16:20:00.000</timestamp>
</log>
</logs>'''

def logs = new XmlSlurper().parseText(payload)
def result = []
logs.log.each{
  result.add( "<log> <text>" + it?.'text'.text() + "</text> <timestamp> " + it?.'timestamp'.text() + "</timestamp> </log>")
}
return result

score 1 · Answer 3 · answered May 18 '17 at 17:03

You can go with:

def payload = '''<logs>
<log>
  <text>LOG 1</text>
  <timestamp>2017-05-18T16:20:00.000</timestamp>
</log>
<log>
  <text>LOG 2</text>
  <timestamp>2017-05-18T16:20:00.000</timestamp>
</log>
</logs>'''

def logs = new XmlParser().parseText(payload) 
def result = logs.log.collect {  
    def sw = new StringWriter()
    def pw = new PrintWriter(sw)
    new XmlNodePrinter(pw).print(it)
    sw.toString().replaceAll('\\s', '')
}

Retrieve a whole node as a string with XmlSlurper

3 Answers3