VB6 Read File with Deutsch Character

Question

Actually, I want to read a text file. And i use this code

Function FileText(filename$) As String
    Dim handle As Integer
    handle = FreeFile
    Open filename$ For Input As #handle
    FileText = Input$(LOF(handle), handle)
    FileText = StrConv(StrConv(FileText, vbUnicode), vbFromUnicode)
    Close #handle
End Function

It works. But unfortunately, when I want to read a text file (in Deutsch, Portuguese, Swedish, etc), it shows some weird character.

Original Text Content : Über Quarantäne Überprüfen

Program Output : Über Quarantäne Überprüfen

I have tried Microsoft Rich TextBox Control too, but it gives me the same result.

How can i fix this problem?

Answer 1

This file is in UTF-8 string format. VB does not provide a mechanism to read this kind of text. You will have to use an API call to transform this to the standard UTF-16 VB String format.

Private Declare Function MultiByteToWideChar Lib "Kernel32.dll" ( _
    ByVal CodePage As Long, _
    ByVal dwFlags As Long, _
    ByRef lpMultiByteStr As Byte, _
    ByVal cbMultiByte As Long, _
    ByVal lpWideCharStr As Long, _
    ByVal cchWideChar As Long _
) As Long

' "Code Page" for UTF8.
Private Const CP_UTF8 As Long = 65001

Function ReadAllFromUtf8TextFile(ByRef the_sFileName As String) As String

    Dim nFileNo     As Long
    Dim abytData()  As Byte
    Dim nDataLen    As Long
    Dim nStringLen  As Long

    ' Get the next available file no.
    nFileNo = FreeFile

    ' Open the file as binary data, resize a Byte array to fit, copy the file contents into the Byte array, and close the file.
    Open the_sFileName For Binary As #nFileNo
    nDataLen = LOF(nFileNo)
    ReDim abytData(1 To nDataLen)
    Get #nFileNo, , abytData()
    Close #nFileNo

    ' Work out the size in characters that the data will be when converted.
    nStringLen = MultiByteToWideChar(CP_UTF8, 0&, abytData(1), nDataLen, 0&, 0&)

    ' Allocate an output string buffer for this number of characters.
    ReadAllFromUtf8TextFile = Space$(nStringLen)

    ' Actually do the conversion of the data in the Byte array to the output string buffer.
    MultiByteToWideChar CP_UTF8, 0&, abytData(1), nDataLen, StrPtr(ReadAllFromUtf8TextFile), nStringLen

End Function

Private Sub Command_Click()

    MsgBox ReadAllFromUtf8TextFile("C:\Document1.txt")

End Sub

Answer 2

You can use ADO as a helper library for this sort of thing:

Dim Text As String

With New ADODB.Stream
    .Type = adTypeText
    .Charset = "utf-8"
    .Open
    .LoadFromFile "utf8.txt"
    Text = .ReadText(adReadAll)
    .Close
End With