Keeping quotations as tuple members in Factor

Question

I want to keep a quotation as a member of a tuple in Factor. But when I try to execute 'call' on it I get the error 'cannot apply call to a run-time computed value'. Note that marking the functions as 'inline' does nothing.

Sample code:

USING: accessors kernel ;
IN: stackoverflow

TUPLE: quottuple quot ;
C: <quottuple> quottuple

: call-quot ( quottuple -- result )
    quot>> call ; inline

: main ( -- )
    [ 1 ] <quottuple>
    call-quot drop ;

MAIN: main

Could you show some code of how you are trying to execute the quotation? — stonemetal, Dec 14 '10 at 15:23

score 5 · Accepted Answer · answered Dec 15 '10 at 07:36

5

The answer is the 'call(' word. That word requires you to specify the stack effect of the quotation, but as a result the quotation doesn't need to be known at compile time.

USING: accessors kernel ;
IN: stackoverflow

TUPLE: quottuple quot ;
C: <quottuple> quottuple

: call-quot ( quottuple -- result )
    quot>> call( -- result ) ;

: main ( -- )
    [ 1 ] <quottuple>
    call-quot drop ;

MAIN: main

answered Dec 15 '10 at 07:36

Randy Voet

3,670
4
29
36

You can use `infer` to get the stack effect of a quotation whose stack effect may not be known at compile time. – cat Apr 09 '16 at 02:08

Keeping quotations as tuple members in Factor

1 Answers1