How to place the Groovy in centralized Groovy Library and access that class from any script

Question

I have the below Groovy script which i need to place it in centralized Groovy Library and then access the class mentioned in the Groovy from any script in my Ready API Project Path: D:\GroovyLib\com\Linos\readyapi\util\property\propertyvalidation

//Change the name of the Properties test step below
def step = context.testCase.testSteps['Properties']

//Parse the xml like you have in your script
def parsedXml = new XmlSlurper().parse(file)

//Get the all the error details from the response as map
def errorDetails = parsedXml.'**'.findAll { it.name() == 'IntegrationServiceErrorCode'}.inject([:]){map, entry ->    map[entry.ErrorCode.text()] = entry.Description.text(); map    }
log.info "Error details from response  : ${errorDetails}"

def failureMessage = new StringBuffer()

//Loop thru properties of Property step and check against the response
step.properties.keySet().each { key ->
   if (errorDetails.containsKey(key)) {
       step.properties[key]?.value == errorDetails[key] ?:  failureMessage.append("Response error code discription mismatch. expected [${step.properties[key]?.value}] vs actual [${errorDetails[key]}]")
   } else {
       failureMessage.append("Response does not have error code ${key}")
   }
}
if (failureMessage.toString()) {
  throw new Error(failureMessage.toString())
}

I have created the code in Library as below:

package com.Linos.readyapi.util.property.propertyvalidation
import com.eviware.soapui.support.GroovyUtils
import groovy.lang.GroovyObject
import groovy.sql.Sql

class PropertyValidation
{
    def static propertystepvalidation()
{
//Change the name of the Properties test step below
def step = context.testCase.testSteps['Properties']

//Parse the xml like you have in your script
def parsedXml = new XmlSlurper().parse(file)

//Get the all the error details from the response as map
def errorDetails = parsedXml.'**'.findAll { it.name() == 'IntegrationServiceErrorCode'}.inject([:]){map, entry ->    map[entry.ErrorCode.text()] = entry.Description.text(); map    }
log.info "Error details from response  : ${errorDetails}"

def failureMessage = new StringBuffer()

//Loop thru properties of Property step and check against the response
step.properties.keySet().each { key ->
   if (errorDetails.containsKey(key)) {
       step.properties[key]?.value == errorDetails[key] ?:  failureMessage.append("Response error code discription mismatch. expected [${step.properties[key]?.value}] vs actual [${errorDetails[key]}]")
   } else {
       failureMessage.append("Response does not have error code ${key}")
   }
}
if (failureMessage.toString()) {
  throw new Error(failureMessage.toString())
}

I am not sure what to mention in the def static method. I am new to this process and haven't done that yet. Can someone please guide me! I've read the documentation on Ready API! website. But I'm not clear on that.

I'm not familiar with the Ready API but can't you simply add it to your classpath? — Klitos Kyriacou, Apr 06 '17 at 12:25
No.. this is our client need.. Trying to replicate the process mentioned in the below website. http://readyapi.smartbear.com/features/scripts/library — Kalaiselvan, Apr 06 '17 at 12:30

Rao · Accepted Answer · 2017-04-07T05:54:31.680

ReadyAPI allows users to create libraries and put them under Script directory and reuse them as needed.

Please note that, ReadyAPI does not allow to have a groovy script in the Script directory, instead it should be Groovy classes.

Looks you were trying to convert a script, answered from one of the previous questions, to class.

Here there are certain variables available in Groovy Script by SoapUI. So, those needs to passed to library class. For instance, context, log are common.

And there can be some more parameters related to your method as well. In this case, you need to pass the file, property step name etc.

Here is the Groovy Class which isconverted from the script. And the method can be non-static or static. But I go with non-static.

package com.Linos.readyapi.util.property.propertyvalidation

class PropertyValidator {

    def context
    def log

    def validate(String stepName, File file) {
        //Change the name of the Properties test step below
        def step = context.testCase.testSteps[stepName]

        //Parse the xml like you have in your script
        def parsedXml = new XmlSlurper().parse(file)

        //Get the all the error details from the response as map
        def errorDetails = parsedXml.'**'.findAll { it.name() == 'IntegrationServiceErrorCode'}.inject([:]){map, entry ->    map[entry.ErrorCode.text()] = entry.Description.text(); map    }
        log.info "Error details from response  : ${errorDetails}"

        def failureMessage = new StringBuffer()

        //Loop thru properties of Property step and check against the response
        step.properties.keySet().each { key ->
            if (errorDetails.containsKey(key)) {
                step.properties[key]?.value == errorDetails[key] ?:  failureMessage.append("Response error code discription mismatch. expected [${step.properties[key]?.value}] vs actual [${errorDetails[key]}]")
            } else {
                failureMessage.append("Response does not have error code ${key}")
            }
        }
        if (failureMessage.toString()) {
            throw new Error(failureMessage.toString())
        } 
    }
}

Hope you already aware where to copy the above class. Note that this also has package name. So copy it in the right directory. I have suggestion here regarding your package name which is so long, you can change it to something like com.linos.readyapi.util. Of course, upto you.

Now here is how you can use / call the above class or its methods from a Groovy Script test step of a test case in the different soapui projects:

Groovy Script step

import com.Linos.readyapi.util.property.propertyvalidation.PropertyValidator

def properties = [context:context, log:log] as PropertyValidator
//You need to have the file object here
properties.validate('Properties', file)

Thanks @Rao.. Well drafted answer and i clearly understand.. It works:) As usual you rocked:):) — Kalaiselvan, Apr 07 '17 at 05:53
Can you please explain what this statement infers? **def properties = [context:context, log:log] as PropertyValidator** — Kalaiselvan, Apr 07 '17 at 05:57
Not clear, which statement? May you can http://chat.stackoverflow.com/rooms/140141/soapui — Rao, Apr 07 '17 at 06:07
It is just instantiating class with argument, like how you were trying to do, but in a different way(map as your class). It is possible to create an object of class differently in groovy. Please refer [documentation](http://groovy-lang.org/objectorientation.html) — Rao, Apr 07 '17 at 06:13

score 1 · Answer 2 · answered Apr 06 '17 at 22:30

Ah! a utility library you mean? Assuming you have placed your groovy library file in this path

D:\GroovyLib\com\Linos\readyapi\util\property\propertyvalidation

If you are using soapui then set above path as the value of below field,

File>preferences>SoapUiPro>Script Library

If you are using ready api then,

File>preferences>Ready! API>Script Library

Then call your method by initializing the class first

PropertyValidation classObject = new PropertyValidation()
classObject.propertystepvalidation()
//you might need to pass some parameters which are declared/initiated outside this class

How to place the Groovy in centralized Groovy Library and access that class from any script

2 Answers2