Erlang - Convert Strings into Binaries

Question

Is there any good way to convert strings located in lists/tuples into binary data? for example:

input:

[{"start", [{"data", [{"number",[{"@id","333"},{"#text","test message"}]}, {"data","current date"}]}, {"mass", [{"client","35"}, {"address","lattitude"}, {"code","3454343"}, {"foo",[{"@tipo","casa"},{"#text","Some text message 2"}]}, {"product","TEST"}]}]}]

output:

[{<<"start">>, [{<<"data">>, [{<<"number">>,[{<<"@id">>,<<"333">>},{<<"#text">>,<<"test message">>}]}, {<<"data">>,<<"current date">>}]}, {<<"mass">>, [{<<"client">>,<<"35">>}, {<<"address">>,<<"lattitude">>}, {<<"code">>,<<"3454343">>}, {<<"foo">>,[{<<"@tipo">>,<<"casa">>},{<<"#text">>,<<"Some text message 2">>}]}, {<<"product">>,<<"TEST">>}]}]}]

something like this one

[list_to_binary(X) || X <- ["1","2","3"]].

but inside another lists and tuples

I have proplist which I could convert into JSON but the issue that JSX accept only binaries.

Is your input data fixed to the same 3 element tuples (id, created and article)? or could it vary? — Asier Azkuenaga, Apr 03 '17 at 12:18
@AsierAzkuenaga nope. theoreticaly it could be different sizes, but should be {key, val} structure so I could convert it into json via jsx (for example) — Eugen Dubrovin, Apr 03 '17 at 12:21

score 4 · Accepted Answer · edited Apr 03 '17 at 14:09

Use:

-module(test).
-compile(export_all).

to_binary({Term1, Term2}) ->
    {to_binary(Term1), to_binary(Term2)};
to_binary([{_Term1, _Term2}|_Objs]=Terms) ->
    [to_binary(Term) || Term <- Terms];
to_binary(Term) when erlang:is_list(Term) ->
    erlang:list_to_binary(Term);
to_binary(Term) when erlang:is_number(Term) ->
    Term;
to_binary(true) ->
    true;
to_binary(false) ->
    false;
to_binary(Term) when erlang:is_atom(Term) ->
    erlang:list_to_binary(erlang:atom_to_list(Term));
to_binary(Term) ->
    Term.

I run above function using your input:

p@Jahanbakhsh ~/Projects/Test $ erl
Erlang/OTP 19 [erts-8.2.2] [source-1ca84a4] [64-bit] [smp:8:8] [async-threads:10] [hipe] [kernel-poll:false]

Eshell V8.2.2  (abort with ^G)
1> c(test).
{ok,test}

2> Input = [{"start", [{"data", [{"number",[{"@id","333"},{"#text","test message"}]}, {"data","current date"}]}, {"mass", [{"client","35"}, {"address","lattitude"}, {"code","3454343"}, {"foo",[{"@tipo","casa"},{"#text","Some text message 2"}]}, {"product","TEST"}]}]}].
[{"start",
  [{"data",
    [{"number",[{"@id","333"},{"#text","test message"}]},
     {"data","current date"}]},
   {"mass",
    [{"client","35"},
     {"address","lattitude"},
     {"code","3454343"},
     {"foo",[{"@tipo","casa"},{"#text","Some text message 2"}]},
     {"product","TEST"}]}]}]

3> test:to_binary(Input).
[{<<"start">>,
  [{<<"data">>,
    [{<<"number">>,
      [{<<"@id">>,<<"333">>},{<<"#text">>,<<"test message">>}]},
     {<<"data">>,<<"current date">>}]},
   {<<"mass">>,
    [{<<"client">>,<<"35">>},
     {<<"address">>,<<"lattitude">>},
     {<<"code">>,<<"3454343">>},
     {<<"foo">>,
      [{<<"@tipo">>,<<"casa">>},
       {<<"#text">>,<<"Some text message 2">>}]},
     {<<"product">>,<<"TEST">>}]}]}]
4>

this is huge. thank you thats what i need. Also added fun list_to_binary when I accumulate the proplist. thx a lot again. you're always helping me when I post the question — Eugen Dubrovin, Apr 03 '17 at 13:27

Erlang - Convert Strings into Binaries

1 Answers1