0

This question is attached to this post https://stackoverflow.com/questions/42848197/bison-flex-cannot-print-out-result?noredirect=1#comment72805876_42848197

this time I try to make my calculator program accepts both integers and floats numbers.

Thank you.

Here is my code

Flex:

%{
    #include <stdio.h>
    #include "f1.tab.h"
%}

integer [1-9][0-9]*|0
float [0-9]+\.[0-9]+

%%

{integer}   { yylval.ival = atoi(yytext); return INT; }
{float}     { yylval.fval = atof(yytext); return FLOAT; }
.           { return yytext[0]; }

%%

Bison :

%{
    #include <stdio.h>
%}

%union {
    int ival;
    float fval;
}
%token <ival> INT
%token <fval> FLOAT


%type <fval> exp
%type <fval> fac
%type <fval> f

%%
input: line
    | input line
;

line: exp ';'  { printf("%d\n", $1); };

exp: fac             { $$ = $1;         }
  | exp '+' fac     { $$ = $1 + $3;    }
  | exp '-' fac     { $$ = $1 - $3; }
;
fac: f
    | fac '*' f     { $$ = $1 * $3; }
    | fac '/' f     { $$ = $1 / $3; }
;
f: INT | FLOAT;
%%
main(int argc, char **argv) {
    yyparse();
}
yyerror(char *s) {
    fprintf(stderr, "error: %s\n", s);
}
Community
  • 1
  • 1
MohameD ELQUCHIRI
  • 39
  • 1
  • 10

1 Answers1

1

Bison tells you exactly what the problem is:

parser.y:32.4-6: warning: type clash on default action: <fval> != <ival> [-Wother]
 f: INT | FLOAT;
    ^^^

The default action for the rule f: INT copies an ivar to an fvar without any sort of conversion (basically, copying via union). To fix it, you need to insert a conversion:

 f: INT { $$ = (double)$1; }
Chris Dodd
  • 119,907
  • 13
  • 134
  • 226