How to iterate nested PersistentArrayMap in Clojure/Script

Question

After executing a query against the db, the return of the fuction is the list of maps:

({:id 1 :name "Book 1" :category "Drama"}
 {:id 2 :name "Book 2" :category "Drama"}
 {:id 3 :name "Book 3" :category "Poetry"}
 {:id 4 :name "Book 4" :category "Poetry"}
 {:id 5 :name "Book 5" :category "Fantasy"}
 {:id 6 :name "Book 6" :category "Fantasy"}
 {:id 7 :name "Book 7" :category "Fantasy"}
 {:id 8 :name "Book 8" :category "Science fiction"}
 {:id 9 :name "Book 9" :category "Science fiction"}
 {:id 10 :name "Book 10" :category "Science fiction"}
 ...)

So, I group data by category and group-by function returns a persistent array-map contains strs keys and vector of maps as vals:

{"Fantasy" [{:category "Fantasy", :name "Book 5", :id 5} 
            {:category "Fantasy", :name "Book 6", :id 6} 
            {:category "Fantasy", :name "Book 7", :id 7}], 
 "Drama" [{:category "Drama", :name "Book 1", :id 1} 
          {:category "Drama", :name "Book 2", :id 2}], 
 "Poetry" [{:category "Poetry", :name "Book 3", :id 3} 
           {:category "Poetry", :name "Book 4", :id 4}], 
 "Science fiction" [{:category "Science fiction", 
                     :name "Book 8", 
                     :id 8} 
                    {:category "Science fiction", 
                     :name "Book 9", 
                     :id 9} 
                    {:category "Science fiction", 
                     :name "Book 10", 
                     :id 10}]}

Next, I do this:

(doseq [[k [{:keys [id name]} v]] data]
  (println k)
  (println id name))

The side-effect is:

Drama
1 Book1
Poetry
3 Book3
Fantasy
5 Book5
Science fiction
8 Book8

doseq returned only one value for each key.

How can I get the rest of the values? The result must be:

Drama
1 Book1
2 Book2
Poetry
3 Book3
4 Book4
Fantasy
5 Book5
6 Book6
7 Book7
Science fiction
8 Book8
9 Book9
10 Book10

Answer 1

you can just make an inner loop like this:

(doseq [[k vs] data]
  (println k)
  (doseq [{:keys [id name]} vs]
    (println id name)))

or using single doseq:

(doseq [[k vs] data
        {:keys [id name] :as v} vs]
  (when (= v (first vs))
    (println k))
  (println id name))

also there is one more dirty way to print outer loop string once:

(doseq [[k vs] data
        :when (or (println k) true)
        {:keys [id name] :as v} vs]
  (println id name))

or even like this:

(doseq [[k vs] data
        {:keys [id name] :as v} (do (println k) vs)]
  (println id name))