Delphi 10, Berlin, popup menu and hide-show

Question

On a Form, I have TrayIcon and PopupMenu components.

• the PopupMenu is assigned to the Form and TrayIcon.
• in the TrayIcon's OnClick event, I show the Form.
• the PopupMenu has 2 items to show/hide the Form.

When I run the project, the Form shows ok. Right-click on the Form, the PopupMenu appears.

On TrayIcon, left-click shows the Form ok.

On TrayIcon, right-click shows the PopupMenu. Select the "SHOW" item, the Form shows ok.

But, after this, the PopupMenu is not enabled anymore. Right-clicking does not work!

Answer 1

Displaying a PopupMenu from a tray icon is a little tricky. There is actually a well-known issue in Windows itself that causes problems, and it is even documented in MSDN:

TrackPopupMenu function

To display a context menu for a notification icon, the current window must be the foreground window before the application calls TrackPopupMenu or TrackPopupMenuEx. Otherwise, the menu will not disappear when the user clicks outside of the menu or the window that created the menu (if it is visible). If the current window is a child window, you must set the (top-level) parent window as the foreground window.

However, when the current window is the foreground window, the second time this menu is displayed, it appears and then immediately disappears. To correct this, you must force a task switch to the application that called TrackPopupMenu. This is done by posting a benign message to the window or thread, as shown in the following code sample:

SetForegroundWindow(hDlg);

// Display the menu
TrackPopupMenu(   hSubMenu,
                  TPM_RIGHTBUTTON,
                  pt.x,
                  pt.y,
                  0,
                  hDlg,
                  NULL);

PostMessage(hDlg, WM_NULL, 0, 0);

To account for this in Delphi, you can set the PopupMenu.AutoPopup property to false and then call the PopupMenu.Popup() method when needed, eg:

procedure TForm1.FormContextPopup(Sender: TObject);
begin
  ShowPopup;
end;

procedure TForm1.TrayIcon1MouseUp(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
begin
  if Button = mbRight then ShowPopup;
end;

procedure TForm1.ShowPopup;
begin
  BringToFront;
  with Mouse.CursorPos do
    PopupMenu1.Popup(X, Y);
  PostMessage(Handle, WM_NULL, 0, 0);
end;

Answer 2

I observed the PopUpMenu's "AutoPopup" property was false on the show event; setting it back restored expected behavior:

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.Menus, Vcl.ExtCtrls;

type
  TForm1 = class(TForm)
    PopupMenu1: TPopupMenu;
    Show1: TMenuItem;
    Hide1: TMenuItem;
    TrayIcon1: TTrayIcon;
    procedure Show1Click(Sender: TObject);
    procedure Hide1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Hide1Click(Sender: TObject);

begin
   Hide;
   TrayIcon1.Visible := true;
end;

procedure TForm1.Show1Click(Sender: TObject);

begin
   ///////////////////
   //
   // Comment out this line and app will have OP's observed behavior
   Popupmenu.AutoPopup := true;
   ///////////////////

   Show;
end;

end.

Answer 3

I had the same problem when tried what you did, It seems that the value of form.popupmenu becomes nil when you hide the form, my solution was to add another popupmenu with the same event handlers, assign the first one to the form and the second to the tray icon and it will work.

edit

Sertac Akyuz thanks for the note The Popupmenu.AutoPopup becomes false when hiding the form and not form.popupmenu becomes nil