CharInSet doesn't work with non English letters?

Question

I have updated an application from Delphi 2007 to Delphi 2010, everything went fine, except one statement that compiled fine but not working which is:

If Edit1.Text[1] in ['S','س'] then 
  ShowMessage('Found')
else
  ShowMessage('Not Found')

However, I knew that in will not, so I changed to CharInSet

If CharinSet(Edit1.Text[1],['S','س']) then
  ShowMessage('Found')
else
  ShowMessage('Not Found')

but it never worked when the string is س, but always work with S, even I cast the edt1.Text1 with AnsiChar it always not work Arabic letters.

Am doing anything wrong, or it's not the way CharInSet works?, or that's a bug in CharinSet?

UPDATE:

My Great friend Issam Ali has suggested another solution which's worked fine as it :

  If CharinSet(AnsiString(edt1.Text)[1],['S','س']) then

@dan04, it's TEdit, I have change the code to show it's as edit instead of edt — Mohammed Nasman, Nov 21 '10 at 10:55
The compiler emits the following warning with your CharInSet code: [DCC Warning] Unit5.pas(30): W1061 Narrowing given WideChar constant (#$0633) to AnsiChar lost information — David Heffernan, Nov 21 '10 at 16:15
String type is unicode format in Delphi XE. if (Ch in ['S','س']) // code here — MajidTaheri, Apr 23 '12 at 05:40
About your Update: It is not reliable and it always depends on DefaultSystemCodePage. — Baoquan Zuo, Dec 31 '12 at 01:29

score 17 · Accepted Answer · answered Nov 21 '10 at 11:04

17

CharInSet is useless for the characters above 255. In your case you should use

  case C of
    'S','س' : ShowMessage('Found');
  end;

answered Nov 21 '10 at 11:04

kludg

27,213
5
67
118

Worked fine thank you, I didn't think about, because I thought it will have the same problem as in. – Mohammed Nasman Nov 21 '10 at 11:19

score 3 · Answer 2 · answered Nov 22 '10 at 14:25

This happens because set of char structured type (limited to 256 elements maximum) doesn't support Unicode at all. That is, any characters Ord(ch) > High(AnsiChar) being truncated in the set constructor and warning W1061 about narrowing WideChar to AnsiChar is being emitted. Look at the following testcase:

  { naturally, fails, emits CharInSet() suggestion }
  Result := 'س' in ['S','س'];

  { fails because second argument is set of AnsiChar }
  Result := CharInSet(
    'س',
    ['S','س']
  );

  { workaround for WideChar in AnsiCharSet, fails }
  Result := WideStrUtils.InOpSet(
    'س',
    ['S','س']
  );

  { a syntactical workaround, which finally works }
  Result := WideStrUtils.InOpArray(
    'س',
    ['S','س']
  );

  if Result then
    ShowMessage('PASS')
  else
    ShowMessage('FAIL');

score 2 · Answer 3 · answered Nov 22 '10 at 14:58

In addition.

sets are limited to ordinal values of 256 elements. So AnsiChar fits and (Unicode)Char does not fit. You can use CharInSet to port pre unicode versions of Delphi to the unicode versions. Because of the set limitation, sets are not extremely usefull anymore with Chars.

The reason behind this, is that sets are implemented as bitmasks. You are free to implement your own version of a set. For example:

type
  TSet<T> = class 
  public
    procedure Add(const AElem: T);
    function InSet(const AElem: T): Boolean;
  end;

mas_oz2k1 · Answer 4 · 2017-05-27T01:19:27.960

2

Use TCharHelper.IsInArray as follows:

if Edit1.Text[1].IsInArray(['S','س']) then 
  ShowMessage('Found')
else
  ShowMessage('Not Found');

edited May 27 '17 at 01:19

answered May 27 '17 at 00:53

mas_oz2k1

2,851
3
34
41

score 1 · Answer 5 · answered Nov 21 '10 at 10:23

1

Have you set the encoding of your source file to UTF-8 (right click to open the context menu)? (The default is ANSI iirc, which would not work.)

answered Nov 21 '10 at 10:23

mjn

36,362
28
176
378

Just found http://stackoverflow.com/questions/3341754/ so I think it is not so easy as I thought – mjn Nov 21 '10 at 11:06
I thought about it, but I did't feel that's a feasible solution, I have around 13 letter to compare, using number values will be harder in debugging, but I will use it if I got no other solution :-/. – Mohammed Nasman Nov 21 '10 at 11:15

CharInSet doesn't work with non English letters?

5 Answers5

Linked