3

New to roku/brightscript development: Is it possible to add an object to the global associative array (accessible by all components), that has a method defined as one of the properties, and call that method?

Main.brs:

function Main()
    init()
end function

function init()    
    screen = createObject("roSGScreen") 
    m.port = createObject("roMessagePort")
    screen.SetMessagePort(m.port)

    scene = screen.CreateScene("MainController")
    screen.show()

    o = {
        getName: function() as string
            return "John"
        end function
    }

    setUpGlobal(screen)
    m.global.addFields({mainMethods: o})        

    while(true)
        msg = wait(0, m.port)
        msgType = type(msg)

        if msgType = "roSGScreenEvent"
            if msg.isScreenClosed() then exit while
        end if    
    end while        
end function

function setUpGlobal(p_screen as Object)
    m.global = p_screen.getGlobalNode()
    m.global.id = "GlobalNode"
end function

.. then in another MainController, after running a task and returning data...

MainController.brs

function init()
    loadConfig()
end function


function loadConfig()
    m.config = createObject("roSGNode", "Configurator")
    m.config.observeField("done", "onConfigLoaded")
    m.config.observeField("fail", "onConfigError")
end function 


function onConfigLoaded()
    print "config loaded: " + m.global.mainMethods.getName()
end function


function onConfigError()
    print "config failed to loaded"
end function

When it hits line 16 of MainController, I get this:

Member function not found in BrightScript Component or interface. (runtime error &hf4) in pkg:/components/MainController.brs(16)

This is just a general test of what can/can't be done so please don't comment on whether this is "good practice" or not. I just want to know if it's possible and if so, what am I missing here? Thanks for any help

Nas Banov
  • 28,347
  • 6
  • 48
  • 67
neoRiley
  • 465
  • 6
  • 11

3 Answers3

6

You can have functions as roAssociativeArray values. In fact that is how OO methods are done in BrightScript.

However, you cannot assign functions to fields of a Roku Scene Graph object (roSgNode derivatives)! Either directly or indirectly (nested). It's a limitation of the (current?!) implementation.

You can see list of the field types supported by RSG here https://sdkdocs.roku.com/pages/viewpage.action?pageId=1608549

Yes, it does say to support assocarray and (as of lately) array - but there is a caveat to that! When you assign (or even access) compound objects between threads, a deep copy is made and only the "supported" types make it through - and as you experienced, function is not one of them. All unrecognized data is currently silently dropped, with not even whisper of a warning - so buyer beware.

See https://forums.roku.com/viewtopic.php?f=34&t=96955&p=541965#p541965 for more. Feel invited to add your voice in Roku's developer forum, requesting support of function type by RSG - they tend to listen if enough people complain.

Nas Banov
  • 28,347
  • 6
  • 48
  • 67
  • Marking this as the answer - thanks for the in-depth explanation! I'll head over to the forums... :) – neoRiley Dec 21 '16 at 23:04
1

You can't pass functions in node's fields. Only data. If you check m.global.mainMethods.getName value right after setting it, it will be invalid.

Eugene Smoliy
  • 934
  • 4
  • 9
  • Thanks very much - the docs do say that it's a roSGNode object being returned as described in [getGlobalNode() docs](https://sdkdocs.roku.com/display/sdkdoc/ifRoSGScreen#ifRoSGScreen-getGlobalNode()asroSGNode) - I guess the confusion comes in where the docs say you can assign anonymous functions as values in an roAssociativeArray, and then in the docs for roSGNode, it says that it implements/supports ifAssociativeArray ( [roSGNode docs](https://sdkdocs.roku.com/display/sdkdoc/roSGNode) ). In testing, I can verify that any method passed to global is definitely invalid. Marking as the answer. – neoRiley Dec 21 '16 at 16:40
0

I think you can do this with anonymous functions.

https://developer.roku.com/en-gb/docs/references/brightscript/language/program-statements.md#anonymous-functions

q = { 
    starring : Function(o, e)
        str = e.GetBody()
        print "Starring: " + str 
        toks = box(str).tokenize(",")
        For Each act In tok
            actx = box(act).trim()
            If actx <> "" Then
                print "Actor: [" + actx + "]"
                o.Actors.Push(actx)
            End If
        End For
        Return 0
    End Function 
} 

q.starring(myobj, myxml)
Jonny
  • 15,955
  • 18
  • 111
  • 232