In Perl what is the difference between double quotes("), single quotes(') and grave accent(`)

Question

In Perl, what is the difference between quoting with double quotes("), single quotes('), and grave accents(`)?

This code:

#!/bin/env perl
use v5.10;
say "Hello";
say 'Hi';
say `Hola`;

gives the following result:

Hello
Hi

Answer 1

Single quotes ''

Construct strings without interpolation. There is also a q() operator that does the same.

my $foo = 'bar';
print '$foo'; # prints the word $foo
print q($foo); # is equivalent

You would use single quotes when you just have text and there are no variables inside the text.

Double quotes ""

Construct strings with interpolation of variables. There is also a qq() operator that does the same.

my $foo = 'bar';
print "$foo"; # prints the word bar
print qq($foo); # is equivalent

Use these if you want to put variables into your string. A typical example would be in an old-fashioned CGI program, where you see this:

print "<td>$row[0]</td>";

The qq() variant comes in handy if your text contains double-quotes.

print qq{<a href="$url">$link_text</a>}; # I prefer qq{} to qq()

This is way easier to read than escape all the quotes.

print "<a href=\"$url\">$link_text</a>"; # this is hard to read

Backticks ``

Shell out and execute a command. The return value of the other program is returned. There is also a qx() operator that does the same. This interpolates variables.

print `ls`; # prints a directory listing of the working directory
my $res = qx(./foo --bar);

Use this if you want to write a script that is a bit more powerful than a shell script, where you need to call external programs and capture their output.

---

All the interpolating ones can only interpolate variables, not commands.

my $foo = 1;
my $bar = 2;
print "$foo + $bar";

This will print 1 + 2. It will not actually calculate and print 3.

---

All of those (and more) are explain in perlop under Quote and Quotelike operators.