need to remove multiple "-" from the string which is alpha numeric using tcl

Question

I have this string:

svpts-7-40.0001

And I need to remove the second '-' from this. Basically I am fetching values like these which would come with double '-' SOMETIMES. So if such variables are seen then I have to remove the second '-' and replace the same with '.' , so the string should look like:

svpts-7.40.0001

---

[EDIT] I have tried:

% set list1 [split $string -]
svpts 7 40.0001
% set var2 [join $list1 .]
svpts.7.40.0001
%

Answer 1

Here's a regular expression that will change only the 2nd hyphen:

% regsub -expanded {( .*? - .*? ) -} "svpts-7-40.0001" {\1.}
svpts-7.40.0001

% regsub -expanded {( .*? - .*? ) -} "svpts-7_40.0001" {\1.}
svpts-7_40.0001

% regsub -expanded {( .*? - .*? ) -} "svpts-7-40.0001-a-b-c" {\1.}
svpts-7.40.0001-a-b-c

Answer 2

Try

% set data svpts-7-40.0001
svpts-7-40.0001
% regexp {([^-]*-)(.*)} $data -> a b
1
% set b [string map {- .} $b]
7.40.0001
% set newdata $a$b
svpts-7.40.0001

The above code changes every hyphen after the first. To change only the second hyphen, one can do this:

set idx [string first - $data [string first - $data]+1]
set newdata [string replace $data $idx $idx .]

or this:

set idxs [lindex [regexp -inline -all -indices -- - $data] 1]
set newdata [string replace $data {*}$idxs .]

The first snippet is well-behaved if the data string doesn't contain at least two hyphens; the other needs some kind of checking to avoid throwing an error.

Documentation: lindex, regexp, set, string, {*} (syntax), Syntax of Tcl regular expressions

Syntax of Tcl index expressions:

• integer zero-based index number
• end the last element
• end-N the nth element before the last element
• end+N the nth element after the last element (in practice, N should be negative)
• M-N the nth element before element m
• M+N the nth element after element m

There can be no whitespace within the expression.