Linking against an ExternalProject_add dependency in CMAKE

Question

I'm getting this ninja build error below while running Ninja. My CMAKE build command iscmake -G"Ninja" -DCMAKE_BUILD_TYPE=Release.

ninja: error: 'ext_deps/api/src/ext_api/build/src/lib/libapi.a', needed by 'Project', missing and no known rule to make it

Let's say my project consists of an API (downloaded via CMAKE from GitHub) and the implementation (the Project).

The layout would look like:
Project/
-- build/
-- cmake/modules
----- ExternalDep.cmake
----- FindAPI.cmake
-- CMakeLists.txt
-- src/
---- CMakeLists.txt
-- include/

Let's say that in the top-level CMakeLists.txt I do the usual business of setting build settings, CXX flags, et cetera, and then I call include(ExternalDep), which checks if the "API" library is in the user's system (if not it is downloaded via CMAKE). In src/CMakeLists.txt I try to link against the API library using a

target_link_libraries(${PROJECT_NAME} PRIVATE ${API_LIBRARY})

The first issue I'm having is that before the "API" library can even be downloaded and built, I get the ninja build error I posted above. I'm positive the ExternalDep.cmake is included before I try to add the Project executable and link against the "API" library.

Here's a simplified version of ExternalDep.cmake:

  set(EXT_DEPS_PREFIX "ext_deps")

  ExternalProject_Add(ext_lib
    GIT_REPOSITORY "https://github.com/fake/api.git"
    GIT_TAG "master"
    PREFIX "${CMAKE_BINARY_DIR}/${EXT_DEPS_PREFIX}/api"
    TMP_DIR "${CMAKE_BINARY_DIR}/${EXT_DEPS_PREFIX}/api-tmp"
    STAMP_DIR "${CMAKE_BINARY_DIR}/${EXT_DEPS_PREFIX}/api-stamp"
    CMAKE_ARGS -DCMAKE_BUILD_TYPE=Release
    SOURCE_DIR "${CMAKE_BINARY_DIR}/${EXT_DEPS_PREFIX}/api/ext_api"
    BINARY_DIR "${CMAKE_BINARY_DIR}/${EXT_DEPS_PREFIX}/api/ext_api-build"
    BUILD_ALWAYS true
    TEST_COMMAND "")

  add_dependencies(ext_projects ext_api)

  set(API_LIBRARY "${CMAKE_BINARY_DIR}/${EXT_DEPS_PREFIX}/api/ext_api-build/src/lib/libapi.a")

`ExternalProject_Add` builds the project on **build stage**. But `FindXXX.cmake` expects the XXX project being already installed at *configure stage*. If you want to build project at configure stage, use `execute_process()`. — Tsyvarev, Oct 29 '16 at 21:50
@Tsyvarev So after much fiddling around I found out that all I needed to do was use `Unix Makefiles` as my generated build files instead of `Ninja`. Not sure why this is the case but it worked. — BlazePascal, Oct 31 '16 at 21:57

score 18 · Answer 1 · answered May 01 '17 at 05:01

I ran into the same issue with Ninja while it worked fine with Unix Makefiles, and I managed to get it to work with Ninja by adding a BUILD_BYPRODUCTS line to my ExternalProject_Add block. Example:

    ExternalProject_Add(SDL2_PROJECT
        PREFIX 3rdparty
        URL https://www.libsdl.org/release/SDL2-2.0.5.tar.gz
        URL_MD5 d4055424d556b4a908aa76fad63abd3c
        CONFIGURE_COMMAND <SOURCE_DIR>/configure ${SDL2_configure_args} --prefix=<INSTALL_DIR> --disable-shared
        INSTALL_COMMAND make install -j9
        BUILD_BYPRODUCTS <INSTALL_DIR>/lib/libSDL2.a
    )
    ExternalProject_Get_Property(SDL2_PROJECT INSTALL_DIR)
    set(SDL2_INSTALL_DIR ${INSTALL_DIR})
    add_library(SDL2_LIBRARY STATIC IMPORTED GLOBAL)
    set_property(TARGET SDL2_LIBRARY PROPERTY IMPORTED_LOCATION ${SDL2_INSTALL_DIR}/lib/libSDL2.a)
    add_dependencies(SDL2_LIBRARY SDL2_PROJECT)

The BUILD_BYPRODUCTS is required for ninja only, I read somewhere. Nevertheless, I am getting this error with UNIX Makefile because the build order is wrong. I need a dependency of my cmake target that links with the `.a` that the external project is producing on that external project, so the latter will be build first... — Carlo Wood, Dec 17 '19 at 04:37
@CarloWood have you tried creating an imported library that depends on the external project like I did in my code example above? If you do it exactly how I did it, You will only needs to add_target_link_libraries your binary against the imported target and it should all work... — mchiasson, Jan 04 '20 at 15:58

score 0 · Accepted Answer · answered Oct 31 '16 at 22:01

0

I was able to solve this by generating Unix Makefiles instead of Ninja. I'm still not exactly sure if this was the singular issue but it was definitely one of the issues.

answered Oct 31 '16 at 22:01

BlazePascal

391
5
12

3

that's because you need to use `BUILD_BYPRODUCTS`. Have a look at my answer. – mchiasson Jan 04 '20 at 16:03

Linking against an ExternalProject_add dependency in CMAKE

2 Answers2

Linked